if one shape is drawn only once, in front of another shape that is drawn every cycle, and there is no background, the shape in front is never drawn over.

easiest explained with this code:

Code:

PGraphics3 g3;
int numPx;
boolean clearit = false;

boolean firstframe = true;
boolean secondframe = false;

void setup () {
  size(400, 400, P3D);
  numPx = width*height;
  g3 = (PGraphics3) g; 
  noStroke();
}

void draw () {
  //g3.zbuffer = new float[numPx];

  if (secondframe) {
    translate(0, 0, 150);
    fill(0, 255, 0);
    rect(100, 100, 100, 100);
    translate(0, 0, -150);
    secondframe = false;
  }

  if (firstframe) {
    background(0);
    firstframe = false;
    secondframe = true;
  }

  fill(255, 0, 0);
  rect(100, 0, 100, height);
}
 

basically, background is drawn on the first frame.  green square is drawn on the next.  red stripe is drawn every frame.  one would think that drawing the red rect later would draw over the green square, no?

after some digging, i found out a bit about the z-buffer...clearing it fixes this problem.  uncomment the first line in draw() to see what i mean.

so, what *exactly* is the z-buffer?  is it a processing thing, or a java thing, or a drawing-with-computers thing in general?  pleez edumacate me

z-buffer can be categorized in the general drawing-with-computers
Basically it's an array of floats whose size is your viewport's size. Each value of the array stores the distance (z value) of the pixel to the viewer. It is very useful in 3D when intersecting objects are drawn, because a simple comparison allows you to remove hidden surfaces. Somewhere in the drawing pipeline, before a pixel is drawn, its z-value is compared to what is already on the frame buffer : either it is lower/equal and the 'coming' pixel is drawn, either it is greater and the pixel is not drawn.

oh wait!  if i change the line in my GL example from
Code:

   gl.glClear(GL.GL_COLOR_BUFFER_BIT | GL.GL_DEPTH_BUFFER_BIT);
 

to

Code:

   gl.glClear(GL.GL_DEPTH_BUFFER_BIT);
 

it does exactly what i want -- clears the z-buffer without clearing the color buffer.  still dunno how do this in P3D, but that's just trivia as far as i'm concerned, since i'm working in gl.

thanks again for the explanation v3ga, exactly what i needed!
-d

and, for what it's worth to whoever reads this in the future, even faster to use System.arraycopy --

Code:

PGraphics3 g3;
int numPx;

boolean firstframe = true;
boolean secondframe = false;

float[] clearZ;

void setup () {
  size(400, 400, P3D);
  noStroke();
  g3 = (PGraphics3) g; 
  
  numPx = width*height;
  clearZ = new float[numPx];
  for (int i=0; i<numPx; i++) {
    clearZ[i] = MAX_FLOAT;
  }
}

void draw () {
  System.arraycopy(clearZ, 0, g3.zbuffer, 0, numPx);

  if (secondframe) {
    translate(0, 0, 150);
    fill(0, 255, 0);
    rect(100, 100, 100, 100);
    translate(0, 0, -150);
    secondframe = false;
  }

  if (firstframe) {
    background(0);
    firstframe = false;
    secondframe = true;
  }

  fill(255, 0, 0);
  rect(100, 0, 100, height);
}