blendColor() in Processing 3?

Graywolf

I was wondering if there was an alternative to what seems to be an old function called blendColor() that was available in processsing 1. If there isn't, how can I replicate it's function of blending two colors together with a blendmode parameter? Thanks for any advice!

kfrajer

https://processing.org/reference/blend_.html
https://processing.org/reference/tint_.html

Previous posts:

https://forum.processing.org/two/search?Search=blend

Kf

Graywolf

@kfrajer these two functions are fine for blending pixels, but I need to blend colors before they are drawn.

jeremydouglass

@Graywolf --

1. If you only need to blend two colors, you could blend() two 1x1 pixel images.

2. If you need to blend a small array of colors pairs (eg 5 color pairs, 10 color pairs) then store them in two 1xn color images.

3. If you need to blend pairs at different times and and you need a lot of them it probably doesn't make sense to create 2xn number of 1x1 pixel PImages -- at that point you would need a different solution.

kfrajer

You can try https://processing.org/reference/lerpColor_.html and don't forget to keep in mind what color mode you are using (and which one could be more convenient in your situatiuon.... https://processing.org/reference/colorMode_.html ) However, I think what you want is eactly what @jeremydouglass suggested and you have different blending modes available.

Kf

Graywolf

@jeremydouglass Thanks for the answer, it's a kind of hacky solution but I guess that's what happens when the remove a good feature. Thank you!

jeremydouglass

Glad it helped.

I'm not sure whether the old blendColor code can be found in previous github release versions, or if it is still available but undocumented, or only accessible through a PImage instance...? Possibly relevant:

https://github.com/processing/processing/search?utf8=✓&q=blendColor

jeremydouglass

@Graywolf --

Out of curiousity, I just tried using blendColor() in a sketch, and it works just fine -- even if it isn't in the reference.

Here it is in the source code:

• https://github.com/processing/processing/blob/0abee5af6ad3b11cf2b73bb794b8a97c157c4762/core/src/processing/core/PImage.java#L1678

Here is a one-line sketch that sets the background to the EXCLUSION of red and blue:

background(blendColor(color(255,0,0), color(0,0,255), EXCLUSION));

Here's a full demo sketch that cycles through all the modes.

// blendMode demo -- Jeremy Douglass 2017-03-03 -- Processing 3.2.3
color c1,c2,c3;
int[] modes = new int[]{
  BLEND, ADD, SUBTRACT, DARKEST, LIGHTEST,
  DIFFERENCE, EXCLUSION, MULTIPLY, SCREEN,
  OVERLAY, HARD_LIGHT, SOFT_LIGHT, DODGE, BURN
};
String[] modeNames = new String[]{
  "BLEND", "ADD", "SUBTRACT", "DARKEST", "LIGHTEST",
  "DIFFERENCE", "EXCLUSION", "MULTIPLY", "SCREEN",
  "OVERLAY", "HARD_LIGHT", "SOFT_LIGHT", "DODGE", "BURN"
};

void setup(){
  size(200,200);
  c1 = color(192,192,0);
  c2 = color(0,192,192);
  textAlign(CENTER,CENTER);
  frameRate(1);
}
void draw(){
  background(255);
  c3 = blendColor(c1, c2, modes[frameCount%modes.length]);
  fill(c1);
  rect(10,10,30,30);
  fill(c2);
  rect(40,10,30,30);
  fill(c3);
  rect(60,60,80,80);  
  fill(0);
  text(modeNames[frameCount%modeNames.length], width/2, height-20);
}

Graywolf

@jeremydouglass hmm, it didn't seem to work when I tried it but I'll try again, thanks for noticing!

jeremydouglass

Also note that my example was tested on Processing 3.2.3 -- if it doesn't work, check your version. The one-liner should be a good simple test sketch.