Setting img as background - Coordinate out of bounds

nach

Hey guys, I'm trying to display and image as my background in the void setup() but it shows me the ArrayIndexOutOfBoundException: Coordinate out of bounds! error. However, when I use background(img); in the void draw() , it works.

PImage sourceImg;
int dw, dh;

void setup () {
  sourceImg = loadImage("test2.jpg");
  surface.setResizable(true);
  dw = sourceImg.width;
  dh = sourceImg.height;
  surface.setSize(dw, dh);
  background(sourceImg); //HERE IT GIVES ME THE ERROR
}

void draw() {
  //background(sourceImg); //HERE IT WORKS
}

I don't know how to fix this. I need the background image to be drawn one time at the start of the program. What does that error mean?

Thx in advance!

kfrajer

This next should fix it pending Processing version (I believe).

Kf

PImage sourceImg;
int dw, dh;

void settings () {
  sourceImg = loadImage("test2.jpg");
  //surface.setResizable(true);
  dw = sourceImg.width;
  dh = sourceImg.height;
  //surface.setS
  size(dw, dh);
}
void setup () {
  background(sourceImg); //HERE IT GIVES ME THE ERROR
}

void draw() {
  //background(sourceImg); //HERE IT WORKS
}

kfrajer

To access surface:

void setup() {
  size(400, 400);
}

PSurface initSurface() {
  PSurface pSurface = super.initSurface();
  pSurface.setResizable(true);
  return pSurface;
}

void draw() {
  background(0);
  ellipse(mouseX, mouseY, 20, 20);
}

Kf

GoToLoop

https://forum.Processing.org/two/discussion/18033/how-to-set-processing-to-automatically-detect-an-image-size-and-set-it-as-a-background

https://forum.Processing.org/two/discussion/16705/null-pointer-exception-when-loading-image-in-settings-p3-1-1#Item_1

/**
 * Sized to PImage (v1.1)
 * by GoToLoop (2016-Sep-01)
 *
 * forum.Processing.org/two/discussion/18033/
 * how-to-set-processing-to-automatically-detect-
 * an-image-size-and-set-it-as-a-background
 */

PImage bg;

void settings() {
  bg = loadImage("background.jpg");
  size(bg.width, bg.height);
}

void draw() {
  background(bg);
}

nach

Thanks guys!