I know that I can use explode or extrude to get height data and can use this data to make 3d pixel sized blocks.  The problem is that then I have 10,000(or whatever) blocks.
Is there a way to merge these blocks into one watertight shape?  Or is there a better way to get a 2-manifold shape from 2d image information?

What I'm doing is writing a sketch which has a white background.  Onto this background, I'll draw in black.  I'll then extrude the black areas into a 3d shape(the white will be voids).  I'll then export the 3d shape as a STL and have it 3D printed.
I greatly appreciate all the help I've gotten here.  Your generosity has helped me to learn a lot.

You might also take a look at my TerrainSteering example on OpenProcessing.org, which uses the Terrain class of toxiclibs in order to create a fully water tight 3D mesh (with all sides and bottom filled). You can also export the resulting mesh as binary STL like this:

Code:

mesh.saveAsSTL(sketchPath("terrain.stl")); 

In order to help you populating the terrain with image data you can use the code snippet below (parts of which will be part of the next library release as well):

Code:

// elevation of highest point (white pixels in the image)
float maxElevation=1000;
img=loadImage("test/terrain.png");
terrain=new Terrain(img.width, img.height, 50);
// use blue channel for elevation
// (doesn't matter if bitmap is greyscale)
float[] el=getNormalizedArray(img.pixels, 0, 255, 255,maxElevation);
terrain.setElevation(el);
// turn into water tight mesh
// (0 = ground level, can be set to negative values too)
mesh = terrain.toMesh(0);
mesh.saveAsSTL("terrain.stl");

/**
 * Creates a normalized version of the values of the given int[] array.
 * Supports packed integers (e.g. ARGB data) by allowing to specify a
 * bitshift amount & bitmask.
 * 
 * @param input source data
 * @param bits number of bits to right shift each value
 * @param mask bitmask to apply after bitshifting
 * @param peak peak value (in the source domain) to normalize against
 * @param target target peak of normalized values
 */
float[] getNormalizedArray(int[] input, int bits, int mask, int peak, float target) {
  float invPeak = target / peak;
  float[] normalized = new float[input.length];
  for (int i = 0; i < input.length; i++) {
    int val = input[i];
    if (bits > 0) {
      val >>= bits;
    }
    val &= mask;
    normalized[i] = val * invPeak;
  }
  return normalized;
} 

Robert, these points were surely only directed to Cedric's solution though, or? Did you try the other one?

I see, then a terrain approach is really not suitable here, but despair not... I'd reckon a bit of volumeutils will sort you out here:

Code:

/**
 * Loads a B&W image and extrudes black pixels into
 * a watertight 3D mesh.
 * @author toxi
 *
 * Dependencies: toxiclibscore-0018, volumeutils-0004
 * (or newer, available from: http://toxiclibs.org/ )
 */
import toxi.geom.*;
import toxi.geom.mesh.*;
import toxi.volume.*;

int scale=8;
int depth=32;

PImage img=loadImage("heightmap.gif");
Vec3D worldSize = new Vec3D(img.width, img.height, depth).scale(scale);
VolumetricSpace volume = new VolumetricSpace(worldSize, img.width, img.height, depth);
VolumetricBrush brush = new RoundBrush(volume, scale);
for (int y = 0; y < img.height; y ++) {
  for (int x = 0; x < img.width; x ++) {
    if (0 == (img.pixels[y * img.width + x] & 0xff)) {
      for (int z = 0; z < depth; z++) {
        brush.drawAtGridPos(x, y, z, 0.5f);
      }
    }
  }
}
volume.closeSides();
TriangleMesh mesh = new IsoSurface(volume).computeSurfaceMesh(null, 0.1f);
mesh.saveAsSTL(sketchPath("test.stl"), true);
exit(); 

Btw. You might also like to try the BoxBrush instead of RoundBrush (might give cleaner results). Simply change this one line:

Code:

VolumetricBrush brush = new BoxBrush(volume, scale); 

Hmm.. that'd be weird though and doesn't make much sense (sorry to say too)! Using your image above, the exported model in Meshlab looks fine from both sides (top on left, bottom on right):

We may be getting different resuls.  Here is the file it exported for me:
itsshameful.com/test.stl
and here is a screenshot from magics
itsshameful.com/magics.jpg

another point....Rhino couldn't open it.

yeah....
the problem's on my end, that model looks perfect.
no I didn't change the code.  I thought I had the latest release, I'm so new.  I'll download the latest and see what that does.  I'm sorry for the bother.