import hypermedia.video.*;

OpenCV opencv;
int threshold = 80;
PImage testingFrame;


void setup() {
  size(640,480);
  opencv = new OpenCV(this);
  opencv.capture(width,height);
  testingFrame = new PImage(width, height);
 
  noFill();
  stroke(0,255,0);
}

void draw() {
  //read the video input
  opencv.read(); 
  //make the difference between the current image and the image in memory
  //this is applied to the current opencv image so it changes!
  opencv.absDiff();
  //apply a threshold
  //this is applied to the current opencv image so it changes!
  opencv.threshold(threshold);
  //flip the imae
  //this is applied to the current opencv image so it changes!
  opencv.flip( OpenCV.FLIP_HORIZONTAL );
  //convert it to grayscale
  opencv.convert(OpenCV.GRAY);
  //draw the modified image to the screen
  
  //if we want to compare frames continually turn this on, note you may need to play with 
  //the threshold (click and drag)
  //opencv.remember();
  //copy the current image in openCV into our tesing frame
  testingFrame.copy(opencv.image(), 0, 0, width, height, 0, 0, width, height);
  image( testingFrame, 0, 0 );
  //will print out the true/false this function returns
  println(testAreaMovement(500,380,20,20));
}



//we are returning a value in case you want to use if up the top ie. if (testAreaMovement(.....)) do this
boolean testAreaMovement(int tX, int tY, int tW, int tH) {
  /*Basically what we are going here is going through each pixel in the area we
  are testing. If the pixels is not black either movement or a change has happened
  there. We want to test how many of the pixels in the area are not black, if there is
  a certain amount then we have a "hit"*/
  //hold a value whethere there is a 'hit' or not, assume from the beginning flase
  boolean frameHit = false;
  //how many pixeks are we testing
  float totalNumPixels = tW*tH;
  //how many pixels are not black
  float numNonBlack = 0;
  //create a new image
  PImage test;
  //make it the width and the height of the area we are testing
   test = new PImage(tW,tH);
   //copy the area from testing frame into test
  test.copy(testingFrame,tX,tY,tW,tH, 0,0, tW,tH);
  //load tests pixels
  test.loadPixels();  
  //use a for loop to go through each pixel in test's image
  for (int i = 0; i < test.pixels.length; i++) {
	color currentColor = test.pixels[i];
	//split it up into rgb
	float r1,g1,b1;
	r1 = red(currentColor);
	g1 = green(currentColor); 
	b1 = blue(currentColor); 
	//if the r,g,b are all greater than 15 then assume not black, add that value on to numNotBlack
	if ((r1 > 15) && (g1 > 15) && (b1 > 15)) {
	  numNonBlack++; 
	}
   // } 
  }
  
//  updatePixels();
  //this is a threshold we can change, if we lower it we are looking for less not-black pixels 
  //higher, we are looking for more
  //in this case if 25% of the pixels are not black
  float percHitThreshold = .25;
  //here we find out what percentage of pixels are not-black we divide the number of not-black
  //pixels we counted by the total number of pixels we tested
  float percHitInSquare = numNonBlack/totalNumPixels;
  //print it out so we can see
  println(percHitInSquare);
  //if ther percentage of pixels that are not black in our square is higher than out threshold
  //then its a hit
  if (percHitInSquare > percHitThreshold) {
    //so set frameHit to true
    frameHit = true;
    //make the stroke red
    stroke(255,0,0);
  } else {
    //make the stroke green
    stroke(0,255,0);
  }
  //draw a rect

  rect(tX,tY,tW,tH);
  return frameHit;
}


//if we want to compare from a "plate" frame
void keyPressed() {
  if ( key==' ' ) opencv.remember();
}

//change the threshold
void mouseDragged() {
  threshold = int( map(mouseX,0,width,0,255) );
}

public void stop() {
  opencv.stop();
  super.stop();
}