Show the code you have done so far, ask specific questions, we will answer.

The problem with programmers like me, is that it is difficult to see where you can be stuck.
You were given a link (and example) to random(), so you can draw a number between 1 and 91 with int(random(1, 92)).
You can build the interface with the for loops, as blindfish shown. Have a variable to hold the number, increment it on each loop, starting from the first drawn number, use the variable in the text() call.
That's mostly a bit of simple math (to compute the positions) and logic.

int = RandomNum;

void setup(){
 
 RandomNum = 6
 
 size(270, 270);
 PFont font;
 font = loadFont("CourierNewPS-BoldMT-48.vlw");
 textFont(font);
 
 fill(0, 255, 6);
rect(0, 0, 90, 90);
 fill(0);
 text(RandomNum, 32, 60);
 randomNum++;
 
   fill(255, 255, 0);
rect(90, 0, 90, 90);
fill(0);
text(RandomNum, 122, 60);
randomNum++;

fill(0, 255, 6);
rect(180, 0, 90, 90);
fill(0);
text(RandomNum, 212, 60);
randomNum++;

 fill(255, 255, 0);
rect(0, 90, 90, 90);
fill(0);
text(RandomNum, 32, 150);
randomNum++;

fill(0, 255, 6);
rect(90, 90, 90, 90);
fill(0);
text(RandomNum, 122, 150);
randomNum++;

 fill(255, 255, 0);
rect(180, 90, 90, 90);
fill(0);
text(RandomNum, 212, 150);
randomNum++;

 fill(0, 255, 6);
rect(0, 180, 90, 90);
fill(0);
text(RandomNum, 32, 240);
randomNum++;

 fill(255, 255, 0);
rect(90, 180, 90, 90);
fill(0);
text(RandomNum, 122, 240);
randomNum++;

 fill(0, 255, 6);
rect(180, 180, 90, 90);
fill(0);
text(RandomNum, 212, 240);
randomNum++;
}



This what I have done so far. How close am I to being correct?

Thank you for your help so far, you have been very helpful.

Yes, I have made those changes and it works perfectly fine. So now I basically want to be able to click anywhere on the canvas and the numbers to change randomly. But for the first square to go up to a maximum of 91.

Yes I have done that so it does a random number. But I need for the program to start with the number 1 and then everytime you press on the canvas it will change.

I am struggling with what code to put with the mousepressed. It's obviously got to be whenever you click, all the numbers will change.

I guess to keep the boundaries of 1-91 it would be....

int RandomNum = (random(1,91));

but its putting that kind of code with the mousepressed i am struggling with.

int RandomNum;

void setup(){
 
 size(270, 270);
 PFont font;
 font = loadFont("CourierNewPS-BoldMT-48.vlw");
 textFont(font);

 int RandomNum = 1;
}
 
 void draw() {

 fill(0, 255, 6);
rect(0, 0, 90, 90);
 fill(0);
 text(RandomNum++, 32, 60);
 
   fill(255, 255, 0);
rect(90, 0, 90, 90);
fill(0);
text(RandomNum++, 122, 60);

fill(0, 255, 6);
rect(180, 0, 90, 90);
fill(0);
text(RandomNum++, 212, 60);

 fill(255, 255, 0);
rect(0, 90, 90, 90);
fill(0);
text(RandomNum++, 32, 150);

fill(0, 255, 6);
rect(90, 90, 90, 90);
fill(0);
text(RandomNum++, 122, 150);

 fill(255, 255, 0);
rect(180, 90, 90, 90);
fill(0);
text(RandomNum++, 212, 150);

 fill(0, 255, 6);
rect(0, 180, 90, 90);
fill(0);
text(RandomNum++, 32, 240);

 fill(255, 255, 0);
rect(90, 180, 90, 90);
fill(0);
text(RandomNum++, 122, 240);

 fill(0, 255, 6);
rect(180, 180, 90, 90);
fill(0);
text(RandomNum++, 212, 240);

void mousePressed() {
 int RandomNum = int(random(1,91));
redraw();
}

noLoop()




This is what I have just done. I feel like I am very close to completing this now. Just need to create the mousepressed code to be created. I'm not to sure how to go about it really.

nearly there, yes. your mousepressed looks fine (but see below)

your noLoop() is outside of the draw(), it needs to be inside.

and you're missing the closing } for draw(), should be before your mousePressed() method.

(actually you can get away with it not being there but your code will keep redrawing very fast eating up processor cycles. you won't see any change until you hit the mouse and then it'll start drawing the new numbers very fast, again and again. no point updating the screen if it hasn't changed)

and your
int RandomNum = 1;
and
int RandomNum = int(random(1,91));

is wrong...

int variable = 8;

defines and sets the variable. you only need to define the variable once (at the top there)

variable = 4; or variable = (int)random...

is enough to change the value. by using int you now have 3 different things all called RandomNum but with different scopes... just get rid of the int before RandomNum in setup and mousePressed and just leave it before the top one.

(the convention, btw, is for variable names to start with a lower case letter - 'variableName' and leading uppercase names are used for classes - ClassName. and full capitals are for CONSTANTS)

and where you have blocks of code that's identical apart from the odd number, that's generally a sign that you should make that code either a method or a class... you probably won't gain much with such small repeated blocks but...

and finally, where you are using the same numbers over and over again (90, 180, 32, 150...) it is generally a good idea to replace them with a constant.

oh, didn't see PhiLho's post there 8) actually, he appears to be to blame for the scope problems and the variable name 8)

Sorry - after saying "I can do this" I didn't contribute much help; but I was on holiday

Looks like the OP got there in the end, though I wonder whether it would have been simpler to draw the initial square in setup and thus avoid the need for noLoop().  Also a for loop or two would have avoided duplication of code.  Here's a function to draw the grid using 3 for loops:

Code:

// This function takes a single argument: the start number for the grid
void drawGrid(int inputNum) {
       textAlign(CENTER);
     
    // Draw the first line
    // the for loop repeats 3 times with j equal to 0 then 1 then 2.
    for(int j=0; j<3; j++) {
        // % (modulo) gives you the remainder of a division
        // so if inputNum % 2 == 0 it is even.  This condition can then 
        // be used to alternate the background fill on odd/even squares.
        if(inputNum % 2 ==0) {
          fill(230,230,0);
        }
        else {
          fill(0,200,0);
        }
        // Avoid magic numbers.  by using width/3 and height/3 this will always
       // work regardless of the dimensions set in size()
       // Notice that the x position uses multiples of j so each time through the loop
       // the x position will be shifted: 
       // x = 0*(width/3) = 0
       // x = 1*(width/3) = 90
       // x = 2*(width/3) = 180
        rect(j*(width/3), 0, width/3, height/3);
        fill(0);
        // the position of the text is calculated in a similar way, with an offset added to
        // place it in the middle of the square (note that textAlign(CENTER) is useful in this case)
        text(inputNum++, j*(width/3) + width/6, height/5);
    }
    
    // Draw the second line
    // Notice that the only difference is that the height of the rectangles and text is now offset by height/3
     for(int j=0;j<3;j++) {
        if(inputNum % 2 ==0) {
          fill(230,230,0);
        }
        else {
          fill(0,200,0);
        }
        rect(j*(width/3), height/3, width/3, width/3);
        fill(0);
        text(inputNum++, j*(width/3) + width/6, height/3+ height/5);
    }
     
    // Draw the third line
    // Again notice that the only difference is that the height of the rectangles and text is offset by 2*(height/3)
    // This makes the 3 for loops ideal candidates for a nested loop
    for(int j=0;j<3;j++) {
        if(inputNum % 2 ==0) {
          fill(230,230,0);
        }
        else {
          fill(0,200,0);
        }
        rect(j*(width/3), 2*(height/3), width/3, width/3);
        fill(0);
        text(inputNum++, j*(width/3) + width/6, 2*(height/3)+ height/5);
    } 
} 

OK - so that isn't a great deal less code than the original 'manual' method; but it helps to explain how a nested loop works.  Here it is again with nested loops - there's now a lot less code:

Code:

void drawGrid(int inputNum) {
  textAlign(CENTER);
  // Nested loop
  // Just wrap the original loop with another.  In this case with each repetition of 
  // the outer loop the inner loop is also repeated.  So:
  // i=0, j loop repeats 3 times with j equal to 0,1 and 2
  // i=1, j loop repeats 3 times with j equal to 0,1 and 2
  // i=2, j loop repeats 3 times with j equal to 0,1 and 2
  for(int i=0;i<3;i++){
    // the inner loop is run for each repetition of the outer loop
    for(int j=0;j<3;j++) {
        if(inputNum % 2 ==0) {
          fill(230,230,0);
        }
        else {
          fill(0,200,0);
        }
        // The only change to the original loop is to shift the y position by multiples of i
        // in the same way that the x position is shifted by multiples of j.
        // So for each iteration of the i loop the 3 boxes will be drawn at:
        // y = 0*(height/3) = 0
        // y = 1*(height/3) = 90
        // y = 2*(height/3) = 180
        rect(j*(width/3), i*(height/3), width/3, width/3);
        fill(0);
        // text y position also adjusted using multiples of i
        text(inputNum++, j*(width/3) + width/6, i*(height/3)+ height/5);
    }// end of inner loop
  }
    
} 

OK - so with all the comments it looks like a lot of code so to prove the point here it is without them:

Code:

void drawGrid(int inputNum) {
  textAlign(CENTER);
  for(int i=0;i<3;i++){
    for(int j=0;j<3;j++) {
        if(inputNum % 2 ==0) {
          fill(230,230,0);
        }
        else {
          fill(0,200,0);
        }
        rect(j*(width/3), i*(height/3), width/3, width/3);
        fill(0);
        text(inputNum++, j*(width/3) + width/6, i*(height/3)+ height/5);
    }
  }
    
} 

The really neat thing about the nested structure is that it doesn't just require less code but you can use it to generate a grid of any size.  So instead of setting the loop limits to 3 (and dividing width and height by 3) you could replace this value with a variable and set it to whatever number you want (though in this case you'd also need to tweak a couple of other things to make it position the text correctly).

So - whenever you find yourself repeating the same code over and over, just with different values, figure out the pattern in the values (i.e. do some basic math) and build a loop, or nested loop.  This will save you a lot of time in the long run!