ok so what is the best way to search the arraylist within the code that you so kindly helped with before?

the code im using to get my messages is earlier in the post, not sure how to put it together

i tried changing what you suggested but got error message

cannot invoke size() on the array type string[]

is that because the the example isnt using an arrylist? that thought only just came to me there :S

got that working so another question is how do i then get the trigger to implament drawing something instead of just display the text?

Good timing, I just finished a demo sketch answering your questions...
I anticipated them in my previous answer!
Now, I might have overdone it a bit (adding the Matcher interface), but it was fun...  
For clarity and organization, I made three files:
SearchWordClass.pde Code:

int DISPLAY_FONT_SIZE = 50;
int DISPLAY_TIME = 120; // 2 seconds at 60 FPS
color BACK_COLOR = color(200);

int currentSentenceIdx;
int startFrameCount;
int currentFrameCount;
String currentSentence;
Drawer currentDrawer;

class MatcherAndDrawer
{
  Matcher matcher;
  Drawer drawer;

  MatcherAndDrawer(Matcher m, Drawer d)
  {
    matcher = m;
    drawer = d;
  }
}

MatcherAndDrawer[] triggers =
{
  new MatcherAndDrawer(
      new WordInside("grow"), new Growing()),
  new MatcherAndDrawer(
      new RegExMatcher("(tiny|small|little)", true), 
	new Shrinking()),
  new MatcherAndDrawer(
      new RegExMatcher("fade.*black"), 
	new Fade(BACK_COLOR, #000000)),
  new MatcherAndDrawer(
      new RegExMatcher("fade.*gr[ea]y"), 
	new Fade(BACK_COLOR, #7F7F7F)),
  // Only if at start of sentence!
  new MatcherAndDrawer(
      new RegExMatcher("black.*"), new PlainColor(#000000)),
  new MatcherAndDrawer(
      new WordInside("white"), new PlainColor(#FFFFFF)),
  new MatcherAndDrawer(
      new WordInside("blue"), new PlainColor(#0000FF)),
  new MatcherAndDrawer(
      new WordInside("green"), new PlainColor(#00FF00)),
  new MatcherAndDrawer(
      new WordInside("red"), new PlainColor(#FF0000)),
  // Only as a separate word, but anywhere in the sentence
  new MatcherAndDrawer(
      new RegExMatcher("\\bcyan\\b", true), 
	new PlainColor(#00FFFF)),
  new MatcherAndDrawer(
      new WordInside("magenta"), new PlainColor(#FF00FF)),
  new MatcherAndDrawer(
      new WordInside("yellow"), new PlainColor(#FFFF00))
};

String[] sentences =
{
  "Black Magic Woman",
  "Blue Velvet",
  "Fade to black",
  "Yellow Submarine",
  "Growing and Multiplying",
  "Cyanide and Hapiness",
  "White Christmas",
  "Brown Sugar", // Voluntarily not matching
  "Little House on the pairie",
  "My Baby (Cyan Sleep)",
  "The Black Belt Ninja", // Voluntarily doesn't match "black" matcher
  "The Yellow Brick Road",
  "The Blues Brothers",
  "Steven Spielberg Presents... Tiny Toon Adventures",
  "Greensleeves",
  "Fade to gray",
  "The Red Line",
  "Magenta is rare in song and film names..."
};

void setup()
{
  size(1000, 100);
  background(200);
  PFont f = createFont("Arial Bold", DISPLAY_FONT_SIZE);
  textFont(f);
  UpdateData();
}

void draw()
{
  background(BACK_COLOR);
  currentDrawer.Draw(currentSentence, 10, height - 10, currentFrameCount);
  currentFrameCount++;
  if (frameCount - startFrameCount > DISPLAY_TIME) // Display  a message for a given duration
  {
    currentSentenceIdx++;
    if (currentSentenceIdx == sentences.length)
    {
	background(BACK_COLOR);
	noLoop();
	return;
    }
    UpdateData();
  }
}

void UpdateData()
{
  currentSentence = sentences[currentSentenceIdx];
  println(currentSentence);
  currentDrawer = defaultDrawer;
  for (int t = 0; t < triggers.length; t++)
  {
    if (triggers[t].matcher.IsMatching(currentSentence))
    {
	currentDrawer = triggers[t].drawer;
	break;
    }
  }
  currentFrameCount = 0;
  startFrameCount = frameCount;
}
 

Matchers.pde Code:

interface Matcher
{
  boolean IsMatching(String sentence);
}

class WordInside implements Matcher
{
  String word;

  WordInside(String w)
  {
    word = w;
  }
  boolean IsMatching(String sentence)
  {
    return sentence.toLowerCase().contains(word);
  }
}

class RegExMatcher implements Matcher
{
  String regex;

  RegExMatcher(String re)
  {
    regex = re;
  }
  RegExMatcher(String re, boolean bLoose)
  {
    if (bLoose)
    {
	regex = ".*" + re + ".*";
    }
    else
    {
	regex = re;
    }
  }
  boolean IsMatching(String sentence)
  {
    return sentence.toLowerCase().matches(regex);
  }
}

/*
Other possible variants (can be combined):
- strict: doesn't use toLowerCase
- at start: uses sentence.startsWith()
- at end (endsWith())
- and so on
*/
 

Drawers.pde Code:

Drawer defaultDrawer = new PlainColor(#7F7F7F);

interface Drawer
{
  void Draw(String message, int x, int y, int frame);
}

class PlainColor implements Drawer
{
  color col;

  PlainColor(color c)
  {
    col = c;
  }
  void Draw(String message, int x, int y, int frame)
  {
    fill(col);
    text(message, x, y);
    // I don't use frame here
  }
}

class Fade implements Drawer
{
  color col1, col2;

  Fade(color c1, color c2)
  {
    col1 = c1;
    col2 = c2;
  }
  void Draw(String message, int x, int y, int frame)
  {
    fill(lerpColor(col1, col2, frame / (float) DISPLAY_TIME));
    text(message, x, y);
  }
}

class Growing implements Drawer
{
  Growing()
  {
  }
  void Draw(String message, int x, int y, int frame)
  {
    fill(0);
    textSize(lerp(0, DISPLAY_FONT_SIZE, frame / (float) DISPLAY_TIME));
    text(message, x, y);
  }
}

class Shrinking implements Drawer
{
  Shrinking()
  {
  }
  void Draw(String message, int x, int y, int frame)
  {
    float a = frame / (float) DISPLAY_TIME;
    pushStyle();
    fill(0);
    textSize(lerp(DISPLAY_FONT_SIZE, 0, a));
    float posX = lerp(width - textWidth(message), x, a);
    float posY = lerp(height - DISPLAY_FONT_SIZE, y, a);
    text(message, posX, posY);
    popStyle();
  }
}
 

You can simplify (get rid of the matchers, using "contains" as before) or expand (adding a time of display per word) this code...

Hey guys im really struggling to put together the code that pulls in my strings from my database and the wordclass matcher and drawer, im very confused

I am not too sure how to help you. You should write more precise specifications...

If I understood correctly, you have messages added from time to time to the database table.
My initial program fetches all the new messages from the last check and add them to list of known messages.

Now, we must know how you want to display these messages. Are they displayed permanently? For a given time? One at a time? What to do when there is no new message? Just show a dark screen? A generic message? Restart at beginning, with new messages interrupting this? Etc.

To answer your question, your new classes must use implements Drawer in the class definition, and therefore honor the Drawer contract (that's the role of interfaces) by implementing the Draw() function with these parameters (even if you don't use them all). You can add other methods, but this one is mandatory.

this is the class i tried to add to the drawers not sure what is going wrong as it looks the same as the others

class Circles implements Drawer
{
 Circles()
 {
 }
 void draw(String message, int x, int y, int frame) {
 drawCircles(250, 250, 100, 10);
 }
void drawCircles(float x, float y, int radius, int level)
{
 noStroke();
 float tt = 126 * level / 6.0;
 fill (tt, 0, 116);
 ellipse(x, y, radius*2, radius*2);
 if (level > 1) {
   level = level - 1;
   int num = int (random(2, 5));
   for(int i=0; i<num; i++) {
     float a = random(0, TWO_PI);
     float nx = x + cos(a) * 6.0 * level;
     float ny = y + sin(a) * 6.0 * level;
     drawCircles(nx, ny, radius/2, level);
   }
 }
}

ok that makes sense got that working what about the rest of it   its giving me such a headache