Hi,

Processing uses Java Strings, and as such there would be much more info on such things in just about any Java book. I suggest the Sun's Java tutorial on Strings as a good place to start. Processing books are more likely to focus on the graphics and interactivity aspects of Processing.
For input, you have two choices, roll your own code which accepts key presses and adds them to a string buffer until enter is pressed, or add some text input components. To do the later you will need a basic understanding of an event model and then look at the libraries page for Graphical Interface components.

Regards,

Stephen

Since Processing is all visual, we don't have any support for typing on the console the way that you do in BASIC or a similar language. In Java, you use System.in.readLine() to implement the INPUT command, but that's not available in Processing.

The best thing to do is check out something like the controlp5 library, which will help you get started with a text entry field (I think it has one), or if not, use the keyPressed() method and keep track of keys as they're typed.

Hi Migs,

I don't mean to answer for Fry, and of course I could not if I wanted to. I suspect you are seeing the usefulness (and possibly the general purpose) of Processing differently than its creators. General key and mouse input is extremely easy in Processing, there are built-in methods to handle it. You have a common but special case, the input of an entire line of text, and this is also easy, if you will allow me to demonstrate. The creators cannot (and should not in my opinion) attempt to foresee and implement every possible interaction the user might want, instead they give the building blocks with which to develop your own specialised interactions. The code below assumes you are familiar with the event model of programming. Bewarned, it does not use StringBuffer and it does not handle every key and there is only special processing for backspace and enter. Feel free to ask if you have any questions.

Regards,

Stephen

String lastInput = new String();
String currentInput = new String();

void setup()
{
 size(800, 600);
 smooth();
 PFont font = loadFont("Arial-Black-48.vlw");
 textFont(font);
 textAlign(CENTER);
}

void draw()
{
 background(255, 255, 255);
 fill(0);
 text(lastInput, width/2, height/2);
 fill(255, 0, 0);
 text(currentInput, width/2, height*.75);
}

void keyPressed()
{
 if(key == ENTER)
 {
   lastInput = currentInput = currentInput + key;
   currentInput = "";
 }
 else if(key == BACKSPACE && currentInput.length() > 0)
 {
   currentInput = currentInput.substring(0, currentInput.length() - 1);
 }
 else
 {
   currentInput = currentInput + key;
 }
}

I'd suggest one other condition before the final else:

else if(key == CODED) {
 // ignore...
}

That will take care of SHIFT.  You might also want to consider the following from keyCode:

"If you're making cross-platform projects, note that the ENTER key is commonly used on PCs and Unix and the RETURN key is used instead on Macintosh. Check for both ENTER and RETURN to make sure your program will work for all platforms."