hello all,

i'd like to export some vectors from a sketch which colormode is set to HSB.

i have already a more or less working solution (see below) ... but unfortunately this one is based on "beginRaw()" and as a result of beginRaw() if have to work with the opengl and p3d renders (?) ... but then all my surface a splited in vertices due to the 3d renders. hmm not so cool.

so does anybody know, how to export a pdf in combination with colormode HSB and the default renderer?

thanks benedikt
ps i'm using processing 0135

Code:

import processing.opengl.*;
import processing.pdf.*;
PGraphicsPDF pdf;

boolean dosave=false;

void setup() { 
  size(800, 800, OPENGL); 
  colorMode(HSB, 360, 100, 100);
  noStroke();
} 

void draw() { 

  if(dosave) {
    pdf = (PGraphicsPDF) createGraphics(width, height, PDF, "hsb_test_"+frameCount+".pdf");    
    beginRaw(pdf);
    // set default
    pdf.colorMode(HSB);
    pdf.strokeJoin(MITER);
    pdf.strokeCap(SQUARE);
    pdf.fill(0);
    pdf.noStroke();
    pdf.rect(0,0,width,height);
  }

  fill(120,100,100);
  rect(0,0,width*0.33,height);
  fill(240,100,100);
  rect(width*0.33,0,width*0.33*2,height);
  fill(360,100,100);
  rect(width*0.33*2,0,width,height);

  if(dosave) {
    endRaw();
    dosave=false;
  }
} 

void keyPressed() {  
  if (key == 's' || key == 'S') {
    dosave=true;
    saveFrame("hsb_test_"+frameCount+".png");
  }
}

 

thanks.

tried it in the first time with beginRecord() and the default renderer but that was not working ...

i know now why, the hsb export will just work if you set the colormode in that way:
pdf.colorMode(HSB, 360, 100, 100, 100);
for some reason pdf.colorMode(HSB) (without the explicit values) does not work like expected with beginRecord() ... but then again works correctly with beginRaw()? bug?

anyway now everything is working :)
benedikt

Code:

import processing.pdf.*;
PGraphicsPDF pdf;

boolean dosave=false;

void setup() { 
  size(800, 800); 
  colorMode(HSB, 360, 100, 100, 100);
  noStroke();
} 

void draw() { 
  if(dosave) {
    pdf = (PGraphicsPDF) createGraphics(width, height, PDF, "hsb_test_"+frameCount+".pdf");    
    beginRecord(pdf);
    // set default
    pdf.colorMode(HSB, 360, 100, 100, 100);
    pdf.strokeJoin(MITER);
    pdf.strokeCap(SQUARE);
    pdf.fill(0);
    pdf.noStroke();
    pdf.rect(0,0,width,height);
  }

  fill(120,100,100);
  rect(0,0,width,height);
  fill(240,100,100);
  rect(width*0.33,0,width,height);
  fill(360,100,100);
  rect(width*0.33*2,0,width,height);

  if(dosave) {
    endRecord();
    dosave=false;
  }
} 

void keyPressed() {  
  if (key == 's' || key == 'S') {
    dosave=true;
    saveFrame("hsb_test_"+frameCount+".png");
  }
}

 

okay, thanks i understand now the concept ... for the "beginRecord()" way this should be a correct solution.

benedikt

Code:

import processing.pdf.*;
PGraphicsPDF pdf;

boolean dosave=false;

void setup() { 
  size(800, 800); 
  colorMode(HSB, 360, 100, 100, 100);
  noStroke();
} 

void draw() { 
  if(dosave) {  
    beginRecord(PDF, "hsb_test_"+frameCount+".pdf");
    // call again to set colormode of pdf renderer
    colorMode(HSB, 360, 100, 100, 100);

    // set some defaults
    strokeJoin(MITER);
    strokeCap(SQUARE);

    noStroke();
  }

  fill(120,100,100);
  rect(0,0,width,height);
  fill(240,100,100);
  rect(width*0.33,0,width,height);
  fill(360,100,100);
  rect(width*0.33*2,0,width,height);

  if(dosave) {
    endRecord();
    dosave=false;
  }
} 

void keyPressed() {  
  if (key == 's' || key == 'S') {
    dosave=true;
    saveFrame("hsb_test_"+frameCount+".png");
  }
}