Indeed, using a for-loop to animate an object is not the right way to proceed, and that's why you're stuck.

The code in draw() method is supposed to be executed x times per second. What you are supposed to do is :

 * clear the background
 * draw the sun
 * calculate the coordinates of the planet
 * draw the planet

That means, theta has to be a global variable. See :
http://processing.org/learning/basics/variablescope.html

By the way, i+theta, j+theta are linear coordinates. I guess you would prefer a trajectory that looks like an ellipse : sunPositionX + cos(theta)*ellipseWidth, sunPositionY + sin(theta)*ellipseHeight (saying theta is a float between 0 and TWO_PI).

don't become discouraged! we're here to help

if there is something you don't understand in the code below, just ask.

Code:

float theta = 0.0;

void setup() {
  size(800,600);
  smooth();
}

void draw() {
 background(0);
 sun();
 plotplanet();
}
 
void sun() {
  fill(#FE5502);
  ellipse(400, 280, 55, 55);
}

void plotplanet () {
  theta += PI/80;
  if (theta > TWO_PI) theta -= TWO_PI;
  fill(255);
  ellipse(400 + cos(theta)*150, 280 + sin(theta)*100, 20, 20);
} 

I'll try to explain in english, though it is not my native language. So please excuse me in advance ;-)

To calculate the position of your planet, which has an ellipsoidal trajectory, you have to work with cos & sin. This is the standard equation of an ellipse (you can change the ratios - 150 and 100 - and see what happens, it may flatten the ellipse, for instance) :
x = cos(theta)*150
y = sin(theta)*100

I add 400 to the x position and 280 to the y-position to center the trajectory around the sun.

Theta is the angle of rotation in radians : between 0 and TWO_PI (which is the radian equivalent to a complete rotation). At each frame, theta increases a little (PI/80) so the planet moves a little.

Code:

if (theta > TWO_PI) theta -= TWO_PI; 

This formula is optional, since cos(0) and cos(TWO_PI) and cos(every TWO_PI multiple) return the same. It is just here to check that theta don't get too high, in case you would let the applet run forever (because theta is a float and has an upper limit).

Quote:

object-oriented programming. make your pixel/circle/square an object with x,y coordinates and its own display method. something like :
Code:

class MyEllipse {
  float x, y;
  float size;
  void moveTo(float x, float y) {
    this.x = x;
    this.y = y;
  }
  void display() {
    ellipseMode(CENTER);
    ellipse(x, y, size, size);
  }
} 

Quote:


it is similar to the code above : increase or decrease the angle of rotation. check the cos(), sin() and random() methods in the reference.

Quote:

check the libraries and the learning section, there are some examples.