I'm coming to Processing from ActionScript.

*Obligatory ActionScript specific explanation, feel free to skip this part if you already know ActionScript*

When generating animated content in ActionScript, it's quite common to subclass MovieClip and expose a host of event hooks. Example: to call a method on every frame for an instance of a class that extends MovieClip, you simply write the following in the constructor:

onEnterFrame = update;

This will call the 'update' instance method every time the Flash player enters a new frame.

*End ActionScript Explanation*

So my question is: Do Processing classes have an event hook equivalent to ActionScript's 'onEnterFrame'? It's kind of a pain to have to call an 'update()' method for every instance of a class in the main script's 'draw()' method (especially when dealing with hundreds, or even thousands of instances of a class).

Awesome. That's exactly what I was looking for. I Found an example here: http://www.processinghacks.com/hacks/registerevents#things-to-watch-out-for

Now how do I 'unregisterDraw' if I delete the object? Is it handled automatically by the GC?

You could write your own version of registerDraw...

Code:

interface drawable
{
  void draw();
}

class myClass implements drawable
{
  //normal stuff including a draw method
  myClass()
  {
  }
  
  void draw()
  {
    rect(random(width),random(height),10,10);
  }
}

public class drawManager
{
  ArrayList objs;
  
  drawManager()
  {
    objs=new ArrayList();
    registerDraw(this);
  }

  void addObj(drawable d)
  {
    objs.add(d);
  }

  void remObj(drawable d)
  {
    for(int i=0;i<objs.size();i++)
    {
	if(objs.get(i)==d)
	{
	  objs.remove(i);
	  break; //size of objs has now changed, don't want an exception
	}
    }
  }

  public void draw()
  {
    for(int i=0;i<objs.size();i++)
    {
    ((drawable)objs.get(i)).draw();
    }
  }
}

drawManager dm;
myClass[] things;
void setup()
{
  size(300,300);
  dm=new drawManager();
  things=new myClass[10];
  for(int i=0;i<10;i++)
  {
    things[i]=new myClass();
    dm.addObj(things[i]);
  }
}

void draw()
{
  background(0);
}