Neat.  If i'm reading it right it's a tiled view... similiar to how some digital cameras write lower-res "burst mode" frames to a single image?

I've been wanting to write one that mimics a long film exposure... building up an image over time by "exposing" the pixels.  I'm sure it's easy... but i'm brand new to processing... so much to learn and absorb.

I do love Kyle Mcdonald's AmbientLapse code though, similiar approach to what I want to do... but creates a motion blurred time-lapse instead.

http://www.rpi.edu/~mcdonk/AmbientLapse/

Another project that stacks images captured from a webcam is "Timescape" (http://phantasian.com/timescape/timescape.htm). Instead of tiling, it takes a single-pixel-wide slice and builds a sort of time-panorama.

A similar project with live- video is called TimeLine... very nice.

http://grouplab.cpsc.ucal
gary.ca/papers/2006/06-TimelinesVideo-Nunes-CSCW/abstract.html

Regards,

Tjerk

Hi Tjerk,

This is my version of the code. I guess it coud be optimized but is easy to read in spanish ;)


/*

TimeTwist por Herbert Spencer
Se basa en el concepto la cuarta dimensión por Zbig Rybczynski, 1988

*/

import processing.video.*;

Capture fotograma;
MovieMaker pelc;
PFont px;
PImage[] buffer;
PImage timeTwist;
boolean buffering;
boolean record;
int count;


void setup() {
 size(320, 240);
 //frameRate(60);
 fotograma = new Capture(this, width, height, 24);
 px = createFont("Georgia", 16);
 textFont(px);
 textAlign(CENTER);
 buffering = true;
 buffer = new PImage[height];
 count = 0;

 noStroke();
 fill(255);
}


void draw() {
 if ((fotograma.available() == true) && buffering) {

   fotograma.read();
   buffer[count] = fotograma.get();
   if(count == (height-1)){
     buffering = false;
     timeTwist = fotograma.get();
     //print("done buffering!");
   }
   else{
     //print(count+", ");
     count++;
     background(0);
     rect((width/2)-40, height - count, 80, count);
     text("buffering",(width/2), (height - 8) - count);
   }
 }

 if((fotograma.available() == true) && !buffering){

   // correr todos los valores a la izquierda
   for (int i = 1; i < height; i++){
     buffer[i-1] = buffer[i];
   }

   // poner el nuevo valor al final
   fotograma.read();
   buffer[height-1] = fotograma.get();

   // construir el fotograma "diagonal"
   loadPixels();
   for (int y = 1; y < height; y++){
     for(int x = 0; x < width-1; x++){
       pixels[(width*y) + x] = buffer[y].pixels[(width*y) + x];
     }
   }
   updatePixels();
   //background(timeTwist);
   if(record){
     pelc.addFrame();
   }
 }
}

void keyPressed(){
 if(key == ' '){
   String filename = "movs/"+month()+"-"+day()+"-"+hour()+"-"+minute()+".mov";
   pelc = new MovieMaker(this, width, height, filename, 24, MovieMaker.SORENSON, MovieMaker.HIGH);
   record = true;
   println("GRABANDO");
 }
 if((key == 'q')||(key == 'Q')){
   pelc.finish();
   println("LISTO");
   exit();
 }
}