import java.util.Vector;
 import processing.xml.*;
 
PImage prey;
PImage pred;

Vector robots = new Vector();
XMLElement xml;

void setup() 
{
  size(800,600);
  //Read in the XML
  xml = new XMLElement(this, "test.xml");
  
  //Read in the images
  // BMP is not supported by Processing!
  prey = loadImage("prey.gif");
  pred = loadImage("pred.gif"); 
  
  //For each robot  
  for (int i = 0; i < xml.getChildCount(); i++) {
    XMLElement currentBot = xml.getChild(i);
    //println(currentBot);
    //Select the appropriate image
    Robot current = new Robot(currentBot.getStringAttribute("type").equals("prey") ? prey : pred);
    //Then for each frame of that robot
    for ( int j = 0; j < currentBot.getChildCount(); j++) {
	XMLElement currentFrame = currentBot.getChild(j);
	//println(currentFrame);
	Position pos = new Position(int(currentFrame.getChild(0).getContent()), int(currentFrame.getChild(1).getContent()), float(currentFrame.getChild(2).getContent()));
	//Add the frame to its vector of positions
	//println(pos);
	current.addFrame(pos);
     }
     
     // you actually need robots in your vector to make it work!
	robots.add(current);
  }

  
  frameRate(1);
}

void draw() 
{ 
  background(102);
  // center on screen ...
  translate( width/2, height/2 );
  for (int i = 0; i < robots.size(); i++) {
     ((Robot)robots.get(i)).drawNext();
  } 
}

//Class to aid storing of positions in a vector
class Position {
  int x;
  int y;
  float rot;
 
  Position(int x, int y, float rot){ 
    this.x = x;
    this.y = y;
    this.rot = rot;
  }
    
  String toString() { 
    return "x: "+x+", y: "+y+", rot: "+rot; 
  }

  
  
}

class Robot {
  Vector frames = new Vector();
  PImage sprite;
  int frame = 0;
    
  Robot(PImage sprite) {
    this.sprite = sprite;
  }
  
  //Add a frame from the XML to the vector
  void addFrame(Position pos){
    frames.add(pos);
  }
  
  void drawNext() {
    pushMatrix();
    // remove() will just do that, remove one frame.
    // you will end up with an empty vector which raises an exception when you try to remove another object.
    // i'm using a counter which i update every step here.
    Position pos = (Position)frames.get(frame++);
    // the %= means: if the value to the left is equal or bigger than the one to the right
    // it will be set to zero. otherwise it remains untouched.
    frame %= frames.size();
    pos.toString();
    rotate(pos.rot);
    image(sprite, pos.x, pos.y);
    popMatrix();
  }  
}