Your enthusiasm is awesome, but asking for someone to walk you through how to make a game is a bit broad for a single forum topic. I'm just going to briefly address your question about animated sprites.

As a prelude to that, I should mention that if you are not familiar with the concept of Object-Oriented programming, I'd suggest you read through these tutorials:

http://java.sun.com/docs/books/tutorial/java/index.html

Processing has a class called PImage that makes it easy to load an image you've placed in your sketches "data" folder and then display it on the screen by specifying where you want the left corner to be. You might do something like:

Code:

PImage myImage = loadImage("foo.jpg");
image(myImage, 0, 0);
 

If you want an animated sprite, you could create a class that references all the images needed for the animation and then keeps track of which one it should draw every time you ask it to draw. This class could also keep track of its position so that you didn't have to specify exactly where to draw the sprite every frame (if it's stationary, for example). You don't *need* to create a class to accomplish this, but collecting related data and behaviour into a single class (called encapsulating that data/behaviour) is what using an object-oriented language like Processing (ie Java) is all about. Here's a class that would create something like an animated gif (I haven't tested this, I'm just riffing it into the message box):

Code:

class AnimatedSprite
{
  private PImage[] frames;
  private int currFrame;
  private float frameLength;
  private int timer;
  private float x, y;
 
  AnimatedSprite(PImage[] f, float fps)
  {
    frames = f;
    frameLength = 1000/fps; // set frameLength in milliseconds
    currFrame = 0;
    timer = millis();
    x = 0;
    y = 0;
  }

  void setPosition(float px, float py)
  {
    x = px;
    y = py;
  }

  void draw()
  {
    if ( millis() - timer > frameLength ) 
    { 
	currFrame += 1;
	// this sets the current frame to 0
	// if we've reached the end of the frame array
	currFrame %= frames.length;
	// this resets the timer
	timer = millis();
    }
    image(frames[currFrame], x, y);
  }
}
 

So in your main draw() loop you might have an instance of this class called spinner. When you want it to display you type:

spinner.draw();

If you need to reposition it, you type:

spinner.setPosition(x, y);

Where x and y are floats that have values stored in them.

And if your questions are specific enough you will find lots of people willing to help out on this forum. I look forward to seeing what you put together.

If you try to run any of the Java code in the tutorials from the Processing environment, it won't work. The reason I pointed you to those tutorials is because they explain Objects and Classes and so forth and nothing on the Processing website does.

Processing provides you with the main() funtion that a Java program requires, so you don't need to worry about it. It also provides you with a bunch of functions you can just call, just look at the reference.

To do Hello World in processing all you have to do is start a new sketch, type:

println("Hello World");

and press the play button. You should see your message printed out in the console.

Ok thanks, so to import a java code into processing all I have to do is take the main() etc.? Ok so I think I understand how this works enough to begin programming. I think I'll start with an animated moving sprite. Two things though, how do I make a transparent colour and how can I refreash the screen so the last image does not remain?

Ok, I made a skeleton frame thing to test the basic idea of the class. Once I figure that out, I will make it able to use more kinds of sprites. The syntax is OK, but the delays don't work at all. maybe you can help me fix that? Also, is there any way to give an image a transparent background colour and what does the 'private' thing you said in your cade do?
Other than that I think I'm starting to get this, though the ;s are really annoying.

'private' means that it's not possible to access the variable from outside the class. Typically, you want to make as many class variables private as you can because it enforces encapsulation. If you try to access the variable from outside the class, for example by saying:

mySprite.x = 5;

The compiler will throw an error telling you that's not allowed. In practice, when you are writing a small processing sketch, it's not a big deal to leave off 'private' (processing will add the 'public' modifier), but I tend to put it in out of respect for OOP principles.

You'll have to be more specific about the delays not working for me to be of any help there.

Ah ha. The whole point of the draw() function is so that you can have a program loop to do things like animation and stuff. You shouldn't be using delay() for that, especially not in the middle of a for loop. You need something like this:

Code:

// an array to hold all your images
PImage[] frames;
// an int to keep track of which image to draw
int currFrame;

void setup()
{
  size(600, 600);
  // set the framerate
  // (ie how many times draw will be called per second
  frameRate(30);
  // allocate a four element array of PImages to frames
  frames = new PImage[4];
  // load in the images (arrays are indexed starting from zero)
  frames[0] = loadImage("testball1.GIF");
  frames[1] = loadImage("testball2.GIF");
  frames[2] = loadImage("testball3.GIF");
  frames[3] = loadImage("testball4.GIF");
  currFrame = 0;
}

void draw()
{
  background(200);
  image(frames[currFrame], 50, 50);
  // every thirty frames, increment currFrame
  // the % operator returns the remainder of the 
  // left side divided by the right side
  // so what we are asking here is if frameCount is
  // a multiple of 30
  if ( frameCount % 30 == 0 )
  {
    currFrame++;
    if ( currFrame > 3 ) currFrame = 0;
  }
}
 

For starters, is there anything in that code you don't understand?