I've put together some code to step through a movie frame by frame. I'm using the old infamous iSPEC movie file for this. However, the playhead jumps back and forth when I try to use it.

I'm trying to apply v3ga's edge detection and some of my code to it but this jumping back and forth lark when you advance through the frames looks really awful. I want to save individual frames from the movie and stitch them together later but it's not happening.

Code:

import processing.video.*;
Movie myMovie;
float frameDuration = 0.04;	    //how many frames the movie advances
float playhead = 0.0;			//current location of the playhead
float oldPlayhead = 0.0;
int targetWidth    = 480;
int targetHeight   = 270;
int totalFrames;
boolean newFrame = false;

void setup() {
  size(targetWidth,targetHeight,P3D);
  myMovie = new Movie(this, "test.mov");
  myMovie.loop();
  myMovie.framerate(2);
  println("movie duration:"+myMovie.duration());
  totalFrames = int(myMovie.duration() / frameDuration);
  println("total frames:"+totalFrames);
  println("width:"+myMovie.width+" height"+myMovie.height);
  background(255);
}

void draw()  {
  if (newFrame && oldPlayhead != playhead){
    myMovie.pause();
    newFrame = false;
    image(myMovie,0,0);
    oldPlayhead = playhead;
  }
}

// Events
// ==================================================
void movieEvent(Movie myMovie) {
  myMovie.read();
  newFrame = true;
}
void keyPressed(){
  switch(key){
  case '+':
  case '=':
    stepforward();
    break;
  case '-':
  case '_':
    stepback();
    break;
  }
}
// playhead
// ==================================================
void stepforward(){
  myMovie.play();
  playhead = (playhead+frameDuration)%myMovie.duration();
  myMovie.jump(playhead);
  println(playhead);
}
void stepback(){
  myMovie.play();
  playhead = playhead-frameDuration;
  if (playhead < 0.0){
    playhead += myMovie.duration();
  }
  myMovie.jump(playhead);
  println(playhead);
}
 

Does this code work on other machines? Have I just programmed it wrong or is the Movie object obstinate?

I gave up.

But when I was in a Processing class and was trying to help a student with his movie project I discovered that myMovie.pause() probably should be renamed myMovie.stopAtThisBitUntilPlayIsCalledAgainAndNothingElseWillWork(). But that's not to say we shouldn't do that. But it's not a pause in the conventional sense. The other way of saying pause that seems to make sense conventionally is myMovie.speed(0).

So, open Processing, goto your menu bar and select: Open > Examples > Library-Video > MoviePlayback

That will give you a movie to read for this demo. Then paste the following code over the existing code. And that should answer your question.
Code:

import processing.video.*;
Movie myMovie;
void setup(){
  size(200, 200);
  background(0);
  myMovie = new Movie(this, "station.mov");
  myMovie.loop();
  myMovie.speed(0);
}
void movieEvent(Movie myMovie){
  myMovie.read();
}
void draw(){
  image(myMovie, 0, 0, width, height);
}
void keyPressed(){
  myMovie.jump((myMovie.time() + 0.1) % myMovie.duration());
}
 

I think I had my trouble back before dev.processing and I was already doing a fairly extensive job of harrassing advanced Processing users. I didn't report it because I changed my work to work around the problem. Movie.speed(0) works just fine really.

Here's the Movie Library source. In case anybody else wants to investigate.

My guess is that it's something to do with pause not reading the frames. Perhaps that's better for performance if you're just stopping the video at that point. If it is then there only needs to be a mention in the documentation about use of pause() vs speed(0).

As Fry will already know, I've reported it as a bug for now - but there is a usable workaround.

I just wanted to thank st33d for sharing his work-around solution.  I find that it works fine for what I need right now, and am extremely grateful.  As a newbie, I probably would not have thought of setting the speed to 0.

I haven't modified the code much, but did add back in st33d's forward/reverse switch from his original code, which works fine, and used a DVCProHD 720p movie, which also worked fine, but it does take 5 or more seconds for each frame to display.  Not a problem for me right now, but real-speed smooth video to play back is another matter...

Here is the code as it is for me right now; I wonder, is my thinking in the comments correct?  Is there a frame counter that will tell you the frame number that the playhead is at in the clip?  Converting from seconds to frame numbers seems perilous when all you really care about is the discreet frames.  But I'm new to processing, so I don't know.  Is there any way to take seconds out of the loop?
Code:

import processing.video.*; 
Movie myMovie; 
float frameRate = 29.97;
/************************************************************************
* frameRate is the number of frames per second as a real time duration.  *
* the fact that 29.97 is 30 frames per TC "second" is irrelevant -	    *
* processing only looks at elapsed time, so, alas, the actual frame rate     *
* that is specified in the QT header is the one that needs to be used to     *
* get an accurate frame count here.									    *
*************************************************************************/
float advanceLength = 1/frameRate;

void setup(){ 
  size(1280, 720); 
  background(0); 
  myMovie = new Movie(this, "timeCodeDVCProHD720p30.mov"); 
  myMovie.loop(); 
  myMovie.speed(0); 
} 
void movieEvent(Movie myMovie){ 
  myMovie.read(); 
} 
void draw(){ 
  image(myMovie, 0, 0, width, height); 
} 
void keyPressed(){ 
  switch(key){ 
  case '+': 
  case '=': 
    myMovie.jump((myMovie.time() + advanceLength) % myMovie.duration()); 
    break; 
  case '-': 
  case '_': 
    myMovie.jump((myMovie.time() - advanceLength) % myMovie.duration()); 
    break;
 } 
}
 

I've been playing with this for a while and it seems to work, but I have run into something else that I don't understand.

I seem unable to draw a frame of a quicktime movie from within a control loop.  That is, with myMovie.speed(0),

Code:

image(myMovie, 0, 0, width, height);
 

works as a one-time command, displaying as a still image whichever frame the playhead is at, but putting it in a loop like this:

Code:

 for (int i = 0; i < number; i++) {
	 println("now printing frame " + (i + 1) + " of " + number + " frames");
	 myMovie.jump(myMovie.time() + frameLength);
	 image(myMovie, 0, 0, width, height);
 }
 

produces a new line of text for each would-be frame, but the quicktime image doesn't  update until the 'for' loop is done, and then it jumps 'number' frames in one leap.  This is not what I want; what I want is to display a quicktime frame, then the next, then the next, etc., not at some continuous speed, but one frame at a time.   I've tried inserting various 'delay's and it doesn't help; I've tried letting the 'image' command reside in 'draw' and be triggered by flags, tried putting it in seperate functions, tried making the loop variables global in scope, but I can't get it to work.

Can anyone tell me why it does this, and whether there is a way around it?  I'm about to outsource the control loop to a microprocessor and then have it control 'processing's' display by triggering it one frame per external command, which it can do, but it really seems like it should be able to do this itself, and that I just don't know something (which is hardly new!).

Thanks.