Sorry to start a new thread, but it's the only way to respond as the other one has been locked...

The TGA loader would actually work with 24bit images too, however the TGA you pointed to doesn't seem to stick to the proper format convention. It does mention 24bits/pixel, but doesn't have a value for the number of bits per colour channel. This is what my code didn't like (as I've been checking for 8bits/colour). Below is a patched version which still will only read uncompressed 24 or 32bit images, though it's a little bit more unprejudiced/unassuming...

Code:

PImage loadTGA(String filename) {
  byte[] buffer = loadBytes(filename);

  // [toxi20050929] changed format validation
  // only number of bits/pixel are checked now...
  if (buffer[2] == 2 && (buffer[16] == 24 || buffer[16]==32 )) {
    // get image dimensions
    int w = ((buffer[13] & 0xff) << 8) + (buffer[12] & 0xff);
    int h = ((buffer[15] & 0xff) << 8) + (buffer[14] & 0xff);
    // check if image has alpha
    boolean hasAlpha=(buffer[16] == 32);

    // setup new image object
    PImage img = new PImage(w,h);
    img.format = (hasAlpha ? ARGB : RGB);

    // targa's are written upside down,
    // so we need to parse it in reverse
    int index = (h-1) * w;
    // actual bitmap data starts at byte 18
    int offset = 18;

    // read out line by line
    for (int y = h-1; y >= 0; y--) {
	for (int x = 0; x < w; x++) {
	  img.pixels[index + x] =
	  (buffer[offset++] & 0xff) |
	  ((buffer[offset++] & 0xff) << 8) |
	  ((buffer[offset++] & 0xff) << 16) |
	  (hasAlpha ? ((buffer[offset++] & 0xff) << 24) : 0xff000000);
	}
	index -= w;
    }
    return img;
  }
  die("loadImage(): bad targa image format");
  return null;
} 

Ben, if you want to apply the patch to the method in PApplet, only the marked line with the 1st if() statement has changed...

gosh, that's a bit over reacting, isn't it? it was just an if() statement i've changed...

wicked picture, though!
i knew it. sooner or later my secret hideout would be discovered... have a good weekend!