How to combine multiple processing files into one

skruff

Hello everyone,

I have made multiple .pde files with various classes and I want to now combine them into a single .pde. How can I go about doing this? For example, I run main.pde and if I press the "1" button on my keyboard, 1.pde loads full screen on my display. If I press one again, it exits; if I press the "2" button on my keyboard, 2.pde loads full screen on my display. etc. etc.

If I can simply create multiple "header" files, please point me to the correct syntax to do so. I couldn't find much in the search on this topic and most of the examples I found simply load audio, text, video or image files.

Thank you in advance.

Ater

You can create tabs and copy every sketch on a separate one. This would still create multiple sketches in your project folder, but these will be all in one. In order to have a possibility to switch between different part of code execution, use a variable to store a state and change it with the keyboard event. In your draw() you can then create a switch case conditional and call drawing code depending on the state you are in.

Chrisir

You have to write a new container sketch with gives you a menu to start the other sketches.

The container sketch / frame sketch has setup and draw.

Since the other sketches also have their own setup and draw, pls rename them to setup1 and draw1, setup2 and draw2...

• remove size from all setup() here, the only allowed size() is in the framee sketch

• make sure that no functions have the same name

• you can use different tabs but you don't have to.

Chrisir

here is a sketch that shows states as has been mentioned

// program states
final int stateStartScreen = 0;  // consts 
final int stateNormal     = 1;      
//
int state = stateStartScreen ;   // current 
//


void setup()
{
  size( 800, 800, P3D );
  background(0);
} // setup

void draw()
{
  // this calls functions for each state
  switch (state) {

  case stateStartScreen:
    drawForStateStartScreen(); 
    break;

  case stateNormal:
    drawForStateNormal();
    break;

  default:
    // error
    println ("undefined state, error 39");
    break;
    //
  } // switch
} // func

// ----------------------------------------------------

void drawForStateStartScreen() {
  // start screen 
  background(0);
  fill(255);
  String text1 = 
    "This is a small sketch to demonstrate the start screen. \n\n"
    + "\n\n\n"
    +"Press any key.";
  // println(text1);
  text (text1, 30, 50, width-50, 1900);
}

void drawForStateNormal() {
  // MAIN 
  background(0);
  fill(255);
  text ("main program ", 30, 50);
  pushMatrix();
  fill(255, 2, 2);
  translate(width/2-100, height/2+100);
  box (20, 20, 20);
  popMatrix();
} // func

// -------------------------------------------------------

void keyPressed() {
  // this could call functions too for each state
  switch (state) {
    //
  case stateStartScreen:
    // move on 
    state=stateNormal;
    break;

  case stateNormal:
    if (key == CODED) {
      // cursor is for camera
      if (keyCode == UP) {
      }
      else if (keyCode == DOWN) {
      }
      else if (keyCode == RIGHT) {
      }
      else if (keyCode == LEFT) {
      }
      else {
        // nothing
      }
    }
    else { 
      // not key == CODED
      //
    }

    break;

  default:
    println ("undefined state, error 89");
    break;
  } // switch
} // func 

// -------------------------------------------------

void mousePressed() {
  //
  // this could call functions too for each state
  //
  switch (state) {
    //
  case stateStartScreen:
    state = stateNormal;
    break;

  case stateNormal:
    println ("Mouse is different now.");
    break;

  default:
    println ("undefined state, error 107");
    break;
  } // switch
} // func 

//