Why does openGL not work in Processing 3.0?

Aishh

When I use openGL or P3D in Processing 3.0, I don't get an output. Instead I get an error that OPENGL is deprecated.

Chrisir

use P3D instead

but it should still work...

OPENGL is deprecated.

it's not an error in the strict sense, just a remark/warning

I also had problems starting sketches in Win10 because of my avira antivirus (I has to add an exception folder here)

please tag your post with wontstart and click on that tag to find other peoples solutions

please also write which OS you use - Win10?

this runs with processing 3 and Win10 (and also says OPENGL is deprecated btw.)

// arrow

// angles
float incX = 0;
float incY = 0;
float incZ = 0;

float incX2 = 0;
float incY2 = 0;
float incZ2 = 0;

float incX3 = 0;
float incY3 = 0;
float incZ3 = 0;

// ------------------------------------------------------------

void setup() {
  size(600, 400, OPENGL);
}

void draw() {
  background(0);
  lights();

  arrow(100, 100, -110, incX, incY, incZ);
  arrow(300, height/2, 0, incX2, incY2, incZ2);
  arrow(500, 300, -410, incX3, incY3, incZ3);

  incX += .01;
  incY += .01;
  incZ += .02;

  // incX2 += .0005;
  incY2 += .1; 

  incZ3+=.01;
  //
}

// --------------------------------------------------------------

void arrow(float xpos, float ypos, float zpos, 
  float anglex, float angley, float anglez) {

  // some color consts
  final color RED = color(255, 0, 0);
  final color GREEN = color(0, 255, 0);
  final color BLUE = color(0, 0, 255);

  final color LIGHTGRAY = color(111);

  // points in 2D
  final int[] x = {
    -50, 0, 50, 25, 25, -25, -25, -50
  };
  final int[] y = {
    50, 0, 50, 50, 100, 100, 50, 50
  };

  // how thick is the arrow (1/2)
  final int halfOfTheThickness = 12; 

  pushMatrix(); 

  translate(xpos, ypos, zpos);
  rotateX(anglex);
  rotateY(angley);
  rotateZ(anglez);

  // all no Stroke
  noStroke();

  // arrow Form - ceiling 
  fill(RED); // RED
  beginShape();
  for (int i = 0; i<8; i++) {
    vertex(x[i], y[i], -halfOfTheThickness);
  }
  endShape(CLOSE);
  //
  // arrow Form - floor
  fill(RED); // BLUE
  beginShape();
  for (int i = 0; i<8; i++) {
    vertex(x[i], y[i], halfOfTheThickness);
  }
  endShape(CLOSE);
  //
  // walls of the arrow
  fill(BLUE); //  GREEN
  beginShape(QUAD_STRIP);
  for (int i = 0; i<x.length; i++) {
    vertex(x[i], y[i], -halfOfTheThickness);
    vertex(x[i], y[i], halfOfTheThickness);
  }
  endShape(CLOSE);

  popMatrix();
} // func
//