Help with arrays!

Programming Questions

xdemonx456

in Programming Questions • 2 years ago

Hey guys,

I am kinda new to processing and cant seem to work out how the array and ArrayList work. Basically i want to be able to create shapes with my mouse. So i click once and that sets 1 point, click again and that sets another point, then make a rectangle between those two points and have the X coordinates of each end of the rectangle put into an array so they can be read when needed. I need to be able to make multiple rectangles.

If anyone can give me some sample code or some advice on how to do this i would be greatly appreciated.

Thanks,

Calum.

Replies(9)

amnon.owed

Re: Help with arrays!

2 years ago

I personally use arrays for fixed numbers of things (colors, images etc) and ArrayLists for dynamic numbers of things. So in this case I would go for an ArrayList. Check out the commented example below.

Code Example:

// ArrayList to hold a dynamic number of points
ArrayList <PVector> points = new ArrayList <PVector>();
void setup() {
size(800,400);
// if you want point-to-point rectangle change rectMode to CORNERS
rectMode(CORNERS);
// black rectangles
fill(0);
smooth();
}
void draw() {
background(255);
// show all the rectangles from the points in the ArrayList
for (int i=1; i<points.size(); i+=2) {
PVector p1 = points.get(i-1);
PVector p2 = points.get(i);
rect(p1.x,p1.y,p2.x,p2.y);
}
// show a rectangle from the last open point to the mouse
if (points.size() % 2 == 1) {
PVector p = points.get(points.size()-1);
rect(p.x,p.y,mouseX,mouseY);
}
}
void mousePressed() {
// on a mouse click add a point at the mouse position
points.add( new PVector(mouseX,mouseY) );
}
void keyPressed() {
// erase everything
points.clear();
}

xdemonx456

Re: Re: Help with arrays!

2 years ago

Just what i was looking for, thanks man.

Oh and i forgot to add something to my question. Is it possible to delete individual rectangles by say right clicking on them?

Thanks again.

amnon.owed

Re: Re: Help with arrays!

2 years ago

Of course, the general steps would be...

Check if the mouse is inside the rectangle (given the (relative) position of both points).
If so, do something (change the color, increase size, delete etc).

I think given the code examples in this thread you should be able to figure that out. Good luck!

thomas.di..

Re: Help with arrays!

2 years ago

ArrayList<Rectangle> rectangles = new ArrayList<Rectangle>();
Rectangle rect_new = null;
void setup(){
size(400,300);
}
void draw(){
background(255);
fill(50, 100); stroke(0);
if( rect_new != null ){
rect_new.setCorner2(mouseX, mouseY);
rect_new.draw();
}
for(Rectangle r : rectangles )
r.draw();
}
void mouseReleased(){
if( rect_new != null ){
rect_new.setCorner2(mouseX, mouseY);
rectangles.add(rect_new);
rect_new = null;
}
}
void mousePressed(){
if( rect_new == null) {
rect_new = new Rectangle();
rect_new.setCorner1(mouseX, mouseY);
}
}
class Rectangle{
float x_c1, y_c1; // corner 1
float x_c2, y_c2; // corner 2
Rectangle(){
}
void setCorner1(float x, float y){
x_c1 = x;
y_c1 = y;
}
void setCorner2(float x, float y){
x_c2 = x;
y_c2 = y;
}
void draw(){
rect(x_c1, y_c1, x_c2-x_c1, y_c2-y_c1);
}
}

xdemonx456

Re: Re: Help with arrays!

2 years ago

This too also works great thanks.

I like how you have to click and drag.

I forgot to add something in the question though, is it possible to delete individual rectangles by say right clicking on them?

Thanks again.

thomas.di..

Re: Help with arrays!

2 years ago

to delete rectangle per right-click:
( as amnon.owed explained)
.... and you really should try to do this on your own first --> best way to learn new things

ArrayList<Rectangle> rectangles = new ArrayList<Rectangle>();
Rectangle rect_new = null;
void setup(){
size(400,300);
}
void draw(){
background(255);
fill(50, 100); stroke(0);
if( rect_new != null ){
rect_new.setCorner2(mouseX, mouseY);
rect_new.draw();
}
for(Rectangle r : rectangles )
r.draw();
}
void mouseReleased(){
if( mouseButton == LEFT && rect_new != null ){
rect_new.setCorner2(mouseX, mouseY);
rectangles.add(rect_new);
rect_new = null;
}
if( mouseButton == RIGHT){
for(int i = 0; i < rectangles.size(); ){
Rectangle r = rectangles.get(i);
if( r.inside(mouseX, mouseY) )
rectangles.remove(i);
else
i++;
}
}
}
void mousePressed(){
if( mouseButton == LEFT && rect_new == null) {
rect_new = new Rectangle();
rect_new.setCorner1(mouseX, mouseY);
}
}
class Rectangle{
float x_c1, y_c1; // corner 1
float x_c2, y_c2; // corner 2
Rectangle(){
}
void setCorner1(float x, float y){
x_c1 = x;
y_c1 = y;
}
void setCorner2(float x, float y){
x_c2 = x;
y_c2 = y;
}
boolean inside(float x, float y){
return x > x_c1 && x < x_c2 && y > y_c1 && y < y_c2;
}
void draw(){
rect(x_c1, y_c1, x_c2-x_c1, y_c2-y_c1);
}
}

xdemonx456

Re: Help with arrays!

2 years ago

Thank-you so much both of you. Exactly what i was looking for. I now understand more about arrays thanks to both of you

Thanks again for your time and effort.

Calum.

thomas.di..

Re: Re: Help with arrays!

2 years ago

be aware, that ArrayList != Array.

use an array, if you know the exact size, and if you dont intend to delete/add items, this will always be faster, then an arraylist.

If you need to add/delete items, i think an arraylist is the better choice (its very much faster, than having an array, and adding elements with processings append() function)

here's more about it:
http://www.javafaq.nu/java-article1111.html

xdemonx456

Re: Help with arrays!

2 years ago

Ok, thanks for the help.

Calum.

Top Reply

Help with arrays!

Replies(9)

Re: Help with arrays!

Re: Re: Help with arrays!

Re: Re: Help with arrays!

Re: Help with arrays!

Re: Re: Help with arrays!

Re: Help with arrays!

Re: Help with arrays!

Re: Re: Help with arrays!

Re: Help with arrays!

Statistics

Tags

Actions

Related Posts