> Is it possible to control the z indexes from a data file?

yes. the noise was used in the original just as an easy way of getting something to display, saves typing in width * height numbers. but that's what you'll need.

you could try defining the height map as an image - the lighter the pixel the higher it appears.

oh, we've done this:
http://forum.processing.org/topic/basic-displacement-maps#topic/25080000000089037

i have done something similar using an image file for exaple. or a reaction diffusion that is saved in a pgraphics.
ill post the image code here using the brightness as height information.
so a basic heightmap. it also includes stl export. if you dont need that just remove it.

1. //demo creating a simple mesh using a heightmap from an gif image
   // change the height by moving the mouse and export pressing a key
   
   import peasy.*;
   import unlekker.data.*;
   boolean record;
   PeasyCam cam;
   
   PImage img ;
   
   
   int meshSize = 5;
   int resX = 100;
   int resY = 100;
   float[][] val = new float[resX][resY];
   
   void setup() {
     size(900,600,P3D);
     smooth();
     background(255);
      img = loadImage("heightmap.gif");
     //img = loadImage("heightmap2.gif");
     cam = new PeasyCam(this, 0,0,0,600);
   
   
   
   }
   
   void draw() {
   
     translate(-resX/2*meshSize,-resY/2*meshSize);
   
   
   
     for(int x =0; x<resX; x++){
       for(int y =0; y<resY; y++){
         val[x][y] = brightness(img.get(x,y))*mouseX/width;
       }
     }
   
     background(0);
     if (record) {
       beginRaw("unlekker.data.STL",millis()+".stl");
     }
   
   
     for(int x =0; x<resX-1; x++){
       for(int y =0; y<resY-1; y++){
         beginShape();
         colorMode(HSB,255);
         fill( val[x][y],255,255);
   
         vertex(x*meshSize,y*meshSize,val[x][y] );
         vertex((x+1)*meshSize,y*meshSize,val[x+1][y] );
         vertex((x+1)*meshSize,(y+1)*meshSize,val[x+1][y+1] );
         vertex(x*meshSize,(y+1)*meshSize,val[x][y+1] );
   
   
         endShape(CLOSE);
       }
   
     }
   
   
     if (record) {
       endRaw();
       record = false;
     }
   
   }
   
   
   void keyPressed() {
     record = true;
   }
   
   
   
   
   
   
   
   
   
   

great thanks! The image is just what I need, and the code is of great help! Thanks!

This works very great and easily.