/* chromaFilter example
*  left image shows live view
*  right image shows mask of tracked color
*  mouseClick to choose a color in the live video you want to match
* '[' and ']' to increase/decrease threshold value
*  Apr 2010
*  Johnty Wang johntywang@gmail.com
*/

import processing.video.*;

int numPixels;
Capture video;
PImage masked_img;
float U,V; 

static final int V_WIDTH = 320;
static final int V_HEIGHT = 240;
int threshold = 25;

void setup()
{
  U = 50;
  V = 50;
  size(V_WIDTH*2,V_HEIGHT, P2D);
  video = new Capture(this, V_WIDTH, V_HEIGHT, 24);
  video.settings();
  masked_img = new PImage(video.width, video.height, RGB);
  numPixels = video.width*video.height;
  loadPixels();

  for (int i=0; i<numPixels; i++)
  {
    masked_img.pixels[i] = color(0);
  }
}

void draw()
{
  if (video.available())
  {
    video.read();
    image(video,0,0);
  
    // chroma filtering
    for (int i=0; i<numPixels; i++)
    {
      color currColor = video.pixels[i];
      float cU = RGBtoU(currColor);
      float cV = RGBtoV(currColor);    
      // Chroma filtering
      //default values green
      masked_img.pixels[i] = 0xFF00FF00;
      if ( abs(cU-U)<threshold && abs(cV-V)<threshold )
      { 
        //filtered values red
        masked_img.pixels[i] = 0xFFFF0000;
      }
    }
    //updatePixels();


  }
  image(masked_img, video.width, 0);

}

void mousePressed()
{
  // println(mouseX+" "+mouseY);
  if (mouseX*mouseY <numPixels)
  {
    color currColor = video.pixels[mouseY*video.width+mouseX];
    println(red(currColor)+" "+green(currColor)+" "+blue(currColor));
    U = RGBtoU(currColor);
    V = RGBtoV(currColor);
    println(U+" "+V);
  }
}

void keyPressed()
{
  if (key == '[') threshold-= 5;  if (key == ']') threshold+= 5;
  if (threshold > 255) threshold = 255;
  if (threshold < 0) threshold = 0;
  println("threshold="+threshold);
}

float RGBtoU(color currColor)
{
  return -.147*red(currColor) - 0.289*green(currColor) +  0.436*blue(currColor);
}

float RGBtoV(color currColor)
{
  return 0.615*red(currColor) - 0.515*green(currColor) - 0.1*blue(currColor);
}