ani_Circle locked; // Locked is an object instead of boolean.
			 // shows which object is selected
float bdifx = 0.0; 
float bdify = 0.0; 
ani_Circle[] circles = new ani_Circle[15];

void setup() 
{
  size(500, 500);
  noStroke();
  ellipseMode(RADIUS);  

  for(int i=0; i <15; i++)
  {
    circles[i] = new ani_Circle (random(0),random(0), random(2), random(2), random(255),random(255),random(255));
  }
}

void draw() 
{ 
  background(0);  
  for(int i=0; i<15; i++)
  {
    circles[i].update(); 
  }
}


void mousePressed() {
  //Check if cursor is inside any circle and set it as the locked object
  for (int i=0,j=circles.length;i<j;i++) {
    ani_Circle c=circles[i];
    if (mouseX > c.x-c.rad && mouseX < c.x+c.rad && 
	mouseY > c.y-c.rad && mouseY < c.y+c.rad) { 
	locked=c;
	bdifx = mouseX-c.x; 
	bdify = mouseY-c.y; 
    }
  }
}

void mouseDragged() {
  // If there is a locked object, drag it.
  if(locked!=null) {
    locked.x = mouseX-bdifx; 
    locked.y = mouseY-bdify; 
  }
}

void mouseReleased() {
  // Release any locked objects.
  locked = null;
}



class ani_Circle
{
  float x,y,r,g,b;
  float rad=20;
  float xMove,yMove;
  public ani_Circle(float newx, float newy, float newxMove, float newyMove, float r1, float g1,float b1)
  { // constructor
    x = newx;
    y = newy;
    xMove = newxMove;
    yMove = newyMove;
    r = r1;
    g = g1;
    b = b1; 
  }

  void update()
  {
    fill(r,g,b);
    noStroke();
    ellipse(x, y, rad,rad);
    // If this object is not locked, move it.
    if (locked!=this) {
	x+= xMove;
	y+= yMove;
    } 
    // Otherwise, do nothing but randomize colors.
    else {
	r=random(255);
	g=random(255);
	b=random(255);
    }
    if(x<0)
    {
	xMove = -xMove; 
    }
    if(y<0) {
	yMove = -yMove;
    }
    if(x>width) {
	xMove = -xMove;
    }
    if(y>height){
	yMove = -yMove;
    }
  }
}