Maybe take a look at
http://processing.org/discourse/yabb2/num_1267486301.html


Chrisir    

Rather than use ortho() in setup try this
Code:

import processing.opengl.*;

void setup(){
  size(320,240,OPENGL);

}

int i = 0;

void draw(){
  background(127);
  pushMatrix();
  ortho();
  
  // draw ortho stuff here
  popMatrix();

  perspective();
  rect(10,10,30,40);
}
 
 

At least you will see the rectangle.  

You need the Shapes3D library (http://processing.org/reference/libraries/#3d)
and then create the following sketch

Code:

/**
 * Simple program to demonstrate the shape picking feature
 * of this library.
 * Click on the slowly revolving cubes to change their colour.
 * 
 * This demo uses the off-screen buffer version of the pick
 * shape algorithm.
 * 
 * created by Peter Lager 2010
 */

import shapes3d.utils.*;
import shapes3d.*;

import processing.opengl.*;


Box[] box = new Box[10];
float a;
boolean mouseClicked = false;
boolean orthoOn = false;
PMatrix3D orgMat;

void setup(){
  size(200,200,OPENGL);
  orgMat = (PMatrix3D)g.getMatrix();
  cursor(CROSS);
  float size;
  for (int i = 0; i < box.length; i++) {
    size = 5 + (int)random(15);
    box[i] = new Box(this,size,size,size);
    box[i].moveTo(random(-18,18), random(-18,18), random(-18,18));
    box[i].fill(randomColor());
  }
  translate(width/2, height/2);
}

void draw(){
  background(255);
  pushMatrix();
  if(orthoOn){
    background(255,200,200);
    ortho(-width/6,width/6,-height/6,height/6,-100,100);
  }
  else {
    background(200,2550,200);
    perspective();
  }

  camera(70 * sin(a), 10, 70 * cos(a), 0, 0, 0, 0, 1, 0);
  ambientLight(200,200,200);
  directionalLight(128, 128, 128, -1, 0, -1);

  for (int i = 0; i < box.length; i++) {
    box[i].draw();
  }

  if(mouseClicked){
    Shape3D picked = Shape3D.pickShapeB(this,mouseX, mouseY);
    if(picked != null)
      picked.fill(randomColor());
    mouseClicked = false;    
  }
  popMatrix();
  a += 0.002;
  g.setMatrix(orgMat);
  perspective();

  fill(0);
  if(orthoOn)
    text("Orthoganal View",10,30);
  else
    text("Perspective View",10,30);
}

void mouseClicked(){
  mouseClicked = true;
  orthoOn = !orthoOn;
}

int randomColor(){
  return color(random(60,200), random(60,200), random(60,200));
}
 

Weird one!

I also noticed that the cubes changed direction (incorrectly) in perspective mode. It looks like the 3D axis orientation is different between OPENGL and P3D (i.e. one is left handed and the other right handed).

This problem seems to be associated with changes made moving Processing from 1.0.9 to 1.1 because I tried it in 1.0.9 with no problems.