It is possible, but I think you have to define several ranges. At least if you want to display katakana & hiragana along with kanji of various level.
You must use loadFont of a font with characters in the right ranges (Arial Unicode MS for example, or perhaps Cyberbit, Code2002 or MS Gothic/MS Mincho. See also Large, multi-script Unicode fonts.
By loading it in JAVA2D mode (default), it isn't converted to bitmap, so memory is preserved.

According to Wikipedia, the needed ranges are quite compact:
U+3040–U+309F Hiragana
U+30A0–U+30FF Katakana
U+4E00–U+9FBF Kanj
So we need to draw a number in the range 0 to (0xA0-0x40)+(0x100-0xA0)+(0x9FC0-0x4E00)=0x5280 (thanks, Google, for the answer on the computation...) and map it to the correct ranges.
Note that the said kanji range is actually the CJK Unified Ideographs range, grouping Chinese, Japanese and Korean characters, so it is actually a superset of what we need in Japanese.
It could be interesting to limit ourself to the jōyō kanji list, the base 1945 characters first learned by students of Japanese language.
I see, for example, a list in Jouyou kanji list page, need to extract the list of Unicode chars...
Mmm, can get this list from the kanjidic file with a simple grep " G[1-8] " kanjidic, it is easy enough to get the Unicode codes then.

It is quite simple, the char type in Java is just a number representing a character (or a character symbolized by its Unicode codepoint).
And Processing is able to show a single character (actually it decomposes strings into chars, so that's natural for it).

As you guessed, I am interested by the topic. So I started my own sketch. If you just want a final result, just wait a bit. If you want to develop your own, I can refrain from showing my sketch (only in early stages, anyway) if you want.

I just made a little proof-of-concept sketch, to test font usage (discovered I had to use a trick with createFont to avoid OutOfMemory error) and char display.
[EDIT: Added random selection of kana, pos, colors, etc.]
[EDIT 2: Added more fonts, discarding them if not found on system]
Code:

boolean bDebug = false;
String[] fonts = 
{
  "Arial Unicode MS", "MS Gothic", "MS Mincho", 
  "Batang", "Datum", "Gulim",
  "MingLiU", "SimHei", "SimSun"
};
PFont[] jFonts = new PFont[fonts.length];
char character;
int posX, posY;

void setup()
{
  size(700, 700);
  frameRate(1); // 1 frame per second... OK for a slideshow!

  // Define a dummy charset (1 char to use less memory)
  // because Processing really creates the bitmap font
  // even if it won't use it in this mode...
  // So if we don't do that, we will get an out of memory error!
  char[] dummy = new char[1]; dummy[0] = ' ';
  // Create fonts having Japanese chars
  int count = 0;
  for (int i = 0; i < fonts.length; i++)
  {
    jFonts[count] = createFont(fonts[i], 128, true, dummy);
    if (jFonts[count].getFont().canDisplay(demoChars[0]))
    {
	// This font is on the system and supports CJK
	count++;
	println("Using " + fonts[i]);
    }
    else
    {
	println(fonts[i] + " not found.");
    }
  }
  // Discard unsupported fonts
  jFonts = (PFont[]) subset(jFonts, 0, count);
  println(count + " fonts with CJK support found on this system.");
}

char[] demoChars =
{ 
  // The 10 most frequently used kanji (according to kanjidic)
  0x65E5, 0x4E00, 0x4EBA, 0x56FD, 0x4F1A, 0x5E74, 0x5927, 0x5341, 0x4E8C, 0x672C,
  // Semi-randomly chosen chars
  0x98DF, '\u9762', 0x96FB, 38588
};

void draw()
{
  background(#556677);

  if (frameCount % 2 == 1)
  {
    float r = random(3);
    if (r < 1)
    {
	// Hiragana
	character = (char) (0x3041 + random(0x54));
    }
    else if (r < 2)
    {
	// Katakana
	character = (char) (0x30A1 + random(0x57));
    }
    else
    {
	character = demoChars[int(random(demoChars.length))];
    }
    println(hex(character));
    posX = int(5 + random(width - 140));
    posY = int(130 + random(height - 150));
  }

  fill(128 + int(random(128)), 128 + int(random(128)), 128 + int(random(128)));
  textFont(jFonts[int(random(jFonts.length))]);
  text(character, posX, posY);
  
  if (bDebug)
  {
    // Testing limits
    fill(#FF0000);
    text(character, 5, 130);
    text(character, 5, 680);
    text(character, 565, 130);
    text(character, 565, 680);
  }
}
 

Hmm. I'm still missing a link to make a random kanji generator. Have been trying to create numbers with the random function, but I still need a way to convert integers into chars. Well. Will keep digging around.

! Damn! I love the net! Much thanks. I guess I still don't quite understand the data types though. Why is it that when I wrote something direct like

char letter = 36500;   it worked, but when I wrote

int number = 36500;
char letter = number;

then processing said "cannot convert from int to char?" Why aren't the two operations equivalent?

Note that I just updated the code above, trying more fonts, but discarding those not found on the system.
Also added some frequently used kanji.