dear all,

i am trying to use constraints over a custom area so that various particles/forms i am using cannot enter the area and they collide with it. i looked into toxiclib particleconstrain interface, but the only option it gave me was to constrain it in/out of a sphere, inside a worldbound - which is a box, and along a single axis.
ParticleConstraint sphere=new SphereConstraint(new Sphere(new Vec3D(110,111,230), 100), SphereConstraint.OUTSIDE);

is there any function that already exists and that can constrain particles from getting into a box or custom defined area or an OBJ file?

maybe this is possible with toxiclib, but i can't figure it out.
thanks

wov, this seems so easy..

thanks a million. it does what i need...

it would be great if there is a way to do this with obj. or stl files.... i will have a look at this.

thanks.

t

actually when i try to control this so that the threads are not getting into the box, it looks like it is working when i add this:

public void apply(VerletParticle p) {
   // check if particle needs to be constrained
   if (p.isInAABB(box)) {
     // update intersection ray and compute position on bounding box

   //  intersectRay.dir=p.getConstrained(box);
     intersectRay.dir=p.constrain(box);
  //   intersectRay.dir=p.getInverted();
  //  intersectRay.dir=box.sub(p).normalize();
     p.set(box.intersectsRay(intersectRay,0,Float.MAX_VALUE));

   }
 }


the problem is that my multiple threads then become huge, like there are no bounds of the scene. i am not sure why does this happen...

i dont need the scene constrains but i just want them to have the same properties like they had before.
the only thing that i need is to have all the threads not get into a custom box, that is e.g. 800X500X10, and that they don't change their physics, except the boxconstrain...



uf. i guess, i need to tinker more...
thanks anyways,

hi tadr, sorry for the delay, but I also think you misunderstood some of the logic in the constraint logic... For example setting the direction of the intersection ray as you did using this line below MUST be a failure and doesn't make any sense.
Code:

intersectRay.dir=p.constrain(box); // WRONG! :( 

The constrain method is used to clip a point to stay within a given bounding box. Since you've already established in an earlier line above that the point is inside the box, then this method simply does nothing. But on top of that, the context of how you use this method is wrong, since you now also assign this point position as direction for the intersection test ray and this will produce chaotic results you're getting. Instead the direction should be relative to the box position, see my previous post...

Anyway, I've created a new example showing how to use the above BoxConstraint class properly, so hope this helps now for real
Code:

import processing.opengl.*;

import toxi.geom.*;
import toxi.physics.*;
import toxi.physics.constraints.*;

BoxConstraint[] boxes=new BoxConstraint[2];

int NUM_PARTICLES = 100;
int REST_LENGTH=10;

VerletPhysics physics;
VerletParticle head;

void setup() {
  size(1024,576,OPENGL);
  // create 2 boxes
  boxes[0]=new BoxConstraint(new Vec3D(100,-100,-100),new Vec3D(150,100,100));
  boxes[1]=new BoxConstraint(new Vec3D(-150,-100,-100),new Vec3D(-100,100,100));
  // setup physics engine
  physics=new VerletPhysics();
  physics.gravity=Vec3D.Y_AXIS.scale(0.02);
  VerletParticle prev=null;
  // create particle string and assign boxes as constraints to each particle
  for(int i=0; i<NUM_PARTICLES; i++) {
    VerletParticle p=new VerletParticle(new Vec3D((i-NUM_PARTICLES/2)*REST_LENGTH,-200,0));
    for(int j=0; j<boxes.length; j++) {
      p.addConstraint(boxes[j]);
    }
    physics.addParticle(p);
    if (prev!=null) {
      physics.addSpring(new VerletSpring(prev,p,REST_LENGTH, 0.5));
    }
    prev=p;
  }
  // anchor the 1st particle in space 
  physics.particles.get(0).lock();
}

void draw() {
  physics.update();
  background(255);
  noFill();
  translate(width/2,height/2,0);
  rotateX(-0.33);
  rotateY(frameCount*0.01);
  // draw the box obstacles
  for(int i=0; i<boxes.length; i++) {
    boxes[i].draw();
  }
  // draw all springs
  beginShape(LINES);
  for(Iterator i=physics.springs.iterator(); i.hasNext();) {
    VerletSpring s=(VerletSpring)i.next();
    vertex(s.a.x,s.a.y,s.a.z); vertex(s.b.x,s.b.y,s.b.z);
  }
  endShape();
  for(Iterator i=physics.particles.iterator(); i.hasNext();) {
    VerletParticle p=(VerletParticle)i.next();
    ellipse(p.x,p.y,2,2);
  }
}

class BoxConstraint implements ParticleConstraint {

  public AABB box;
  protected Ray3D intersectRay;

  public BoxConstraint(Vec3D min, Vec3D max) {
    this(AABB.fromMinMax(min,max));
  }

  public BoxConstraint(AABB box) {
    this.box=box;
    this.intersectRay=new Ray3D(box,new Vec3D());
  }

  public void apply(VerletParticle p) {
    if (p.isInAABB(box)) {
      intersectRay.dir=box.sub(p).normalize();
      p.set(box.intersectsRay(intersectRay,0,Float.MAX_VALUE));
    }
  }

  public void draw() {
    Vec3D m=box.getMin();
    Vec3D n=box.getMax();
    beginShape(QUAD_STRIP);
    stroke(0);
    vertex(m.x,m.y,m.z); vertex(n.x,m.y,m.z);
    vertex(m.x,n.y,m.z); vertex(n.x,n.y,m.z);
    vertex(m.x,n.y,n.z); vertex(n.x,n.y,n.z);
    vertex(m.x,m.y,n.z); vertex(n.x,m.y,n.z);
    vertex(m.x,m.y,m.z); vertex(n.x,m.y,m.z);
    endShape();
  }
} 

Toxi, what version of toxiclibs are you using? I have 0018 and I get an error and have a question. The first being that physics.gravity is not visible. I can do physics.setGravity(); though. Secondly, what is a Ray3D object and where can I find that in the documentation? Is that part of Processing or Toxiclibs?

Thanks so much for sharing your knowledge, toxiclibs has really accelerated my understanding of programming.

I'm super butt hurt I couldn't attend the Processing Paris workshop...

Sorry for the delay, guys...

Nwallen is pretty much spot on with his reply already, so not much more to add. I'm not a particular fan of enforcing getters/setters everywhere, but I've noticed a few places where this pattern is indeed useful or even needed. E.g. for the Ray3D class, the reason for the setter was to be able to normalize the direction vector at this moment of setting, rather than every time the direction is needed for calculations (so you can actually pass in any vector now) - so this setter is actually speeding things up now too...

http://toxiclibs.org/javadocs/ is indeed the place to look for, but the docs are also included in all downloads (look inside "docs" folder the individual lib packages)

Lastly, in a workshop last weekend in Istanbul, we've quickly adapted the already bundled SoftBodySquare demo to create a 3D cloth simulation with obstacles. During that I've also noticed (once more) the above BoxConstraint logic is too simplistic and actually produces wrong results in many situations. So I've done some changes to the behaviour of this class which now casts the intersection ray from the particle position into the current direction of movement and checks the box surface...

The new demo with the updated BoxConstraint is here (but still undergoing further changes before getting included in the next release):

http://openprocessing.org/visuals/?visualID=9826

Hth!