Hello!

I've been crunching my head now on this for the past few days and I cannot seem to get it to work. It's ever so simple: I'd like a star rotating on it's own axes.

easy no?

I've been checking the forum and the language and the learning bit, came up many things that worked, but when I try to implement it in my own code... it keeps rotating on some unknown axes.

Don't have a clue what I do wrong... still a newbee.

If someone could have a look at it and explain to me what I do wrong, I'd be much obliged.

Here's the Code:

float xpos; 
float ypos;
int sz;
float angle; 

void setup() {
  frameRate(12);
  size(400,400);
  smooth();
  xpos = width/2;
  ypos = height/2;
  sz = width/8;
}

void draw() {
  background(0xFF006600);
  
  angle += PI/240;

  pushMatrix();
  rotate(-angle);
  Star();
  popMatrix();
}

void Star() {

  fill(0xFFFF0000);
  noStroke();

  beginShape();
  vertex(xpos,ypos-sz/2);
  vertex(xpos+sz/6,ypos-sz/6);
  vertex(xpos+sz/2,ypos-sz/11);
  vertex(xpos +sz/4,ypos+sz/8);
  vertex(xpos+sz/3,ypos+sz/2);
  vertex(xpos,ypos+sz/3);
  vertex(xpos-sz/3,ypos+sz/2);
  vertex(xpos-sz/4,ypos+sz/6);
  vertex(xpos-sz/2,ypos-sz/9);
  vertex(xpos-sz/6,ypos-sz/6);
  endShape(CLOSE); 

}
 

Thanks a lot for whoever can help me!

kYra

It is because you rotate your star, then translate it at (xpos, ypos) before drawing it. You should do that backwards : translate, then rotate it, then draw it.

That can't be done if you use xpos and ypos in your Star() function. You should have something like :

Code:

pushMatrix();
  translate(xpos, ypos);
  rotate(angle);
  drawStar();
popMatrix();

void drawStar() {
  // draw something around the origin (0, 0)
  beginShape();
  vertex(0, -sz/2);
  vertex(sz/6, -sz/6);
  ...
  endShape();
} 

edit: sorry for double-explanation, Cedric was quicker!

if you are planning to draw more stars you can put that rotating and translating in your function and simply draw your stars by writing Star(x,y);

Code:

float xpos; 
float ypos;
int sz;
float angle; 

void setup() {
  frameRate(12);
  size(400,400);
  smooth();
  xpos =0;
  ypos = 0;
  sz = width/8;
}

void draw() {
  background(0xFF006600);

  angle += PI/24;



  Star(20,150);
  Star(120,70);
  Star(230,150);
  Star(150,20);
  Star(width/2,height/2);
}

void Star(float x, float y) {


  pushMatrix();
  fill(0xFFFF0000);
  noStroke();

  translate(x,y);
  rotate(-angle);
  beginShape();
  vertex(-12.0, -12.0);
  bezierVertex(-12.0, -12.0, -12.0, -12.0, -12.0, -12.0);
  bezierVertex(-12.0, -12.0, 0.0, -31.0, 0.0, -31.0);
  bezierVertex(0.0, -31.0, 6.0, -14.0, 6.0, -14.0);
  bezierVertex(6.0, -14.0, 22.0, -7.0, 23.0, -7.0);
  bezierVertex(24.0, -7.0, 5.0, 8.0, 5.0, 8.0);
  bezierVertex(5.0, 8.0, 0.0, 30.0, 0.0, 30.0);
  bezierVertex(0.0, 30.0, -11.0, 7.0, -11.0, 7.0);
  bezierVertex(-11.0, 7.0, -31.0, -8.0, -31.0, -8.0);
  bezierVertex(-31.0, -8.0, -13.0, -11.0, -13.0, -11.0);
  endShape();

  popMatrix();

}



 

i know my star sucks

I like all your stars, haha...

but it needs to be just the one

...it will however come under attack later on by some ellipses