one of the major problems is that you use lerpColor but doesnt change the amt parameter (lerpColor(c1, c2, amt)) so even if it would work, the color wouldnt change. But beside that another problem is that you have to call noStroke. cause right now, you are drawing a thin black line arrounc your rects so you dont see the color of the rect.

but a few more things.
Your sketch is much more flexibel if you use, width, and height. as variables. for example. XBack< width . so you can change the size without changing all the paramters. Another thing. You can easily write xBack++ instead of xBack = xBack + 1;
and there was no need to call the first and the last rect outside of the loop. Just start with 0 ...

and i would probably use line instead of rects...

void setup () {
size (1000,600);
}

color from = color ( 0, 0, 0);
color to = color ( 0, 0, 255);

void draw () {
 for ( int i = 0; i < width; i++) {
   color interA = lerpColor(from, to, (float)i/width);
   stroke(interA);
   line(i,0,i,height);
 }
}

Well it is at the top of the list of sections

did you try the code i added to my post. it does exactly what you are asking for. doesnt it ?

one more thing.

how would i start the gradient later?
meaning, i want the first 100 pixels on the x coordinate to be black before the gradient starts?

thanks again!

2 additional alternatives for you:

If you're using P3D or OPENGL renderers you can also just draw a quad and set each vertex color accordingly, like:

Code:

size(400,400,P3D);
beginShape(QUAD);
fill(0);
vertex(0,0);
fill(0,0,255);
vertex(width,0);
vertex(width,height);
fill(0);
vertex(0,height);
endShape(); 

If you want to draw multicolor gradients, you could also give toxiclibs a go (for this next example to work you need to download toxiclibscore & colorutils, both from here).

Code:

import toxi.geom.*;
import toxi.color.*;

void setup() {
  size(1000,100);
}

void draw() {
  ColorGradient grad=new ColorGradient();
  grad.addColorAt(0,TColor.BLACK);
  grad.addColorAt(width,TColor.BLUE);
  grad.addColorAt(mouseX,TColor.RED);
  grad.addColorAt(width-mouseX,TColor.YELLOW);
  ColorList l=grad.calcGradient(0,width);
  int x=0;
  for(Iterator i=l.iterator(); i.hasNext();) {
    TColor c=(TColor)i.next();
    stroke(c.toARGB());
    line(x,0,x,height);
    x++;
  }
}