Good afternoon!
I am encountering an issue with the display of Fonts. When I put a drawLabels() method anywhere except in setup(), the display appears jagged. The font size is not different  

Has anyone encountered this before? Any ideas?

Here is a stripped down version of the code:

PFont font35, font25;
int diameter;

void setup(){
 size(500, 500);
 smooth();
 background(255);
 diameter = 380;
 fill(#eeeeee);
 noStroke();
 ellipse(width/2, height/2, diameter+5, diameter+5);
}

void draw(){
   fill(174,221,20);
   drawLabels();
}

void drawLabels(){
 fill(130);
 font25 = loadFont("ArialNarrow-25.vlw");
 textFont(font25, 25);
 
 font35 = loadFont("ArialNarrow-35.vlw");
 textFont(font35, 35);
 text("This is the text", 15, 40);
}

Code:

PFont font35, font25;
int diameter = 380;

void setup(){
  size(500, 500);
  smooth();
  font35 = loadFont("ArialNarrow-45.vlw");
  // or
  // recommended if not exporting to web applet
  // font35 = createFont("Arial Narrow", 45); 
}

void draw(){
  background(255);
  noStroke();
  fill(#eeeeee);
  ellipse(width/2, height/2, diameter+5, diameter+5);
  drawLabels();
}

void drawLabels(){
  fill(130);
  textFont(font35, 35); 
  text("This is the text", 15, 40); 
} 

Do not initialize PFonts in the draw() or other functions if they repeat in loops or inside the draw() funtion, loading the font from the data folder takes some time, initialize the PFonts in setup() instead. When creating a font with the tools menu, if you can, make the font bigger than it will be displayed make a 35px font for a 25px displayed text, they tend to look better. Update the background on the begining of each draw() cycle. If your aim is trying to keep the circle in the background, then put it as the first thing after the background() update.

The end.

Fantastic!
Thank you for the thorough explanation!
I should have thought better than to move all my font code around in chunks:

font35 = loadFont("ArialNarrow-35.vlw");
textFont(font35, 35);
text("This is the text", 15, 40);

Thanks!

Problem solved!

It's great to be helpful