Hi , i am learning processing , and on the learning way i want to share what i learn with others as i dont see many videotutorials on processing as there should be.


So i would like if you could write some very basic for loops, i want to get as many examples as posible they should be something like :
Code:

size(500,500); 
smooth();
background(255); 




for(int i=0;i<width;i+=10)
{
  ellipse(width-i,i,10,10);
} 

as you can see , newbies like me can understand this pretty good.

so the examples should be very basic, just one for loop by example i think it would be good so we can focus on the for loop but if you have a good example with 3 for loops go ahead.

PLEASE make a small explanation of the example,what i doing what where. thanx !

Then i will try to explain them in a video tutorial, i will try to do this with  variables, if else statements  and so on.

Please give it a try !

thanx !

maybe you can come up with something better looking, but like this :


float xmag, ymag = 0;
float newXmag, newYmag = 0;

void setup()
{
 size(640, 360, P3D);
 noStroke();
 colorMode(HSB,5);
}

void draw() {  
 background(2);

 pushMatrix();
 translate(width/2, height/2, -30);

 newXmag = mouseX/float(width) * TWO_PI;
 newYmag = mouseY/float(height) * TWO_PI;

 float diff = xmag-newXmag;
 if (abs(diff) >  0.01) {
   xmag -= diff/4.0;
 }

 diff = ymag-newYmag;
 if (abs(diff) >  0.01) {
   ymag -= diff/4.0;
 }

 rotateX(-ymag);
 rotateY(-xmag);
 scale(3);

 for(int i=0;i<5;i++){
   for(int j=0;j<5;j++){
     for(int k=0;k<5;k++){
       fill(i,j,k);  
       pushMatrix();
       translate(i*10,j*10,k*10);
       sphere(2);
       popMatrix();
     }
   }
 }

 popMatrix();
}

you are right, we should add a  sphereDetail(10);
run faster now ?

You might recognize this from the reference pages.
http://processing.org/reference/set_.html

Using 2D coordinates for direct access to pixels.
Code:

size(256,256);

loadPixels(); //make sure pixels[] is available

//This:
///*
//1D array access
for (int idx=0; idx<pixels.length; idx++) {
  pixels[idx] = idx | 0xff000000; //mask with 100% alpha to see the colors
}
//*/

//Is the same as:
/*
//From 2D coordinates to 1D array
for (int x=0; x<width; x++) {
  for (int y=0; y<height; y++) {
    
    int idx = y * width + x; //calculate the offset
    pixels[idx] = idx | 0xff000000;
    
  }
}
//*/

updatePixels(); 

I suggest adding some spaces, it helps in reading code.
Also using some constants helps in understanding relationship of various uses:
Code:

size(500, 500); 
smooth();
background(255); 
fill(200, 0, 0);
int EL_SIZE = 20;

for (int i = 0; i < width; i += EL_SIZE)
{
  ellipse(width - i, i, EL_SIZE, EL_SIZE);
} 
 

You can also make variations on some parameters, like fill color:
Code:

size(500, 500); 
smooth();
background(255); 
int EL_SIZE = 20;
color START_COLOR = color(0); // Black
color END_COLOR = color(255, 0, 0); // Red

for (int i = 0; i < width; i += EL_SIZE)
{
  fill(lerpColor(START_COLOR, END_COLOR, (float) i / width));
  ellipse(width - i, i, EL_SIZE, EL_SIZE);
} 

or ellipse size:
Code:

fill(END_COLOR);

for (int i = 0; i < width; i += EL_SIZE)
{
  float elSize = EL_SIZE * 1.414 * i / width;
  ellipse(width - i, i, elSize, elSize);
} 

or on each parameter:
Code:

for (int i = 0; i < width; i += EL_SIZE)
{
  float elSize1 = EL_SIZE * 3.0 * i / width;
  float elSize2 = EL_SIZE * (1.00 - 2.0 * i / width);
  ellipse(width - i, i, elSize1, elSize2);
} 

It shows it is interesting to play with variations on code.