Original example from the Learning Processing book. There is a prompt to try this out in an object oriented manor. Which is the lower section of code that I did.
Code:

// Learning Processing
// Daniel Shiffman

// Example 9-8: A snake following the mouse

// Declare two arrays with 50 elements.
int[] xpos = new int[50]; 
int[] ypos = new int[50];

void setup() {
  size(200,200);
  
  smooth();
  // Initialize all elements of each array to zero.
  for (int i = 0; i < xpos.length; i ++ ) {
    xpos[i] = 0; 
    ypos[i] = 0;
  }
}

void draw() {
  background(255);
  
  // Shift array values
  for (int i = 0; i < xpos.length-1; i ++ ) {
    // Shift all elements down one spot. 
    // xpos[0] = xpos[1], xpos[1] = xpos = [2], and so on. Stop at the second to last element.
    xpos[i] = xpos[i+1];
    ypos[i] = ypos[i+1];
  }
  
  // New location
  xpos[xpos.length-1] = mouseX; // Update the last spot in the array with the mouse location.
  ypos[ypos.length-1] = mouseY;
  
  // Draw everything
  for (int i = 0; i < xpos.length; i ++ ) {
     // Draw an ellipse for each element in the arrays. 
     // Color and size are tied to the loop's counter: i.
    noStroke();
    fill(255-i*5);
    ellipse(xpos[i],ypos[i],i,i);
  }
}
 

My code that just shows one black ellipse that follows the mouse instead of showing a tail.
Code:

Point[] points = new Point[50];

void setup() {
  size(200,200);

  smooth();

  for (int i = 0; i < points.length; i ++ ) {
    points[i] = new Point(0,0);
  }

}

void draw() {
  background(255);


  for (int i = 0; i < points.length-1; i ++ ) {
    points[i] = points[i+1];
  }

  points[points.length-1].setXpos(mouseX);
  points[points.length-1].setYpos(mouseY);
  
  for (int i = 0; i < points.length; i ++ ) {
    noStroke();
    fill(255-i*5);
    ellipse(points[i].getXpos(),points[i].getYpos(),i,i);
  }


}
//////////////////////////////// my Point class below
class Point {
  int ypos, xpos;

  Point(int x, int y) {
    xpos = x;
    ypos = y;
  }
  
  int setXpos(int x) {
    xpos = x;
    return xpos;
  }
  
  int setYpos(int y) {
    ypos = y;
    return ypos;
  }
  
  int getXpos() {
    return xpos;
  }
  
  int getYpos() {
    return ypos;
  }

}
 

another possibility that is much simpler would be correcting the for iteration you use to shift values insides the points[] array. the way i understand it, if you use points[i] = points[i+1] you don't actually shift the values of x and y as you should for the example to work properly.

substituting the for iteration in your code for the following iteration solves the problem, once it specifically shifts values of x and y between the instances of Point.

Code:

  for (int i = 0; i < points.length-1; i ++ ) {
    points[i].setXpos(points[i+1].xpos);
    points[i].setYpos(points[i+1].ypos);
  } 

hope this helps.