Hiya guys, I am currently working on 2 basic sketches, I say basic but for sure I'm not able to implement them
My buddies keep saying it is easy but I wish they would stop it already as I'm new to this completely.
Any help appreciated

I wouldn't be keen on downloading and running some random exe file...
It might be more useful to explain what you are trying to do, and perhaps provide some images.

hey y'all I have miraculously been able to get some of my coding done for one of these programs so was briefly shouting yipee, but that soon changed to god darn it!   I have become stuck so would like to see if any of y'all can help.
I will paste in my code & you will see a sketch producing circles with random colours. I want to add a mouse pressed event, so that a circle disapears wherever I click the mouse. Is it something to do with boolean/mouse X mouse Y? I really suck at this!

int Rank = 12;
int SqSide = 20;
int Side = SqSide * Rank;
color White = color(255, 255, 255),
     Red = color(255, 0, 0),
     Green = color(0, 255, 0),
     Blue = color(0, 0, 255),
     Yellow = color(255, 255, 0),
     Black = color(0, 0, 0);
color BG = Yellow;

void ranCol() {
 float co;  
 co = random(5);
 int n;
 n = (int) co;
 if (n == 0) {
  fill (Green);
 } else {
     if (n == 1) {
       fill (Blue);
     } else {
       if (n == 2) {
         fill (Red);
       } else {
         if (n == 3) {
           fill (Yellow);
         } else {
           if (n == 4) {
             fill (White);
           } else {
             if (n == 5) {
               fill (Black);
        }
      }
     }
     }
     }
}
 
}

//color RandomColor() {
// color Result;
 
 //Result = color((int) random(256), (int) random(256), (int) random(256));
// return(Result);
//}

void setup() {
 size(Side, Side);
 smooth();
 background(BG);  
}

void draw() {

 int a, b;
 float x,
       y;
 int L,
     T;
 int u,
     v;
 x = random(Side)/SqSide;
 y = random(Side)/SqSide;
 L = (int) x;
 T = (int) y;
 u = SqSide * L;
 v = SqSide * T;

 for (a=0; a< Rank;a++) {
  for ( b=0;  b<Rank;b++) {
//fill(RandomColor());
ranCol();
ellipse(a * SqSide + SqSide/2, b*SqSide + SqSide /2, SqSide, SqSide);  
}
 }
}

alright, here it is. You really should take a look at what ive done. and maybe check the OOP tutorial.
there are also some little things you should change about your programming language like naming variables ( use camelCase)
and your for loops for example.

anyway, here it is:



int Rank = 12;
int SqSide = 20;
Circles[] circle = new Circles[Rank*Rank];
int Side = SqSide * Rank;
color White = color(255, 255, 255),
Red = color(255, 0, 0),
Green = color(0, 255, 0),
Blue = color(0, 0, 255),
Yellow = color(255, 255, 0),
Black = color(0, 0, 0);
color BG = Yellow;


void setup() {
 size(Side, Side);
 smooth();
 background(BG);  
 for (int i=0; i< circle.length;i++) {
   circle[i] = new Circles();
 }
}

void draw() {

 background(BG);

 for (int i=0; i< Rank;i++) {
   for (int j=0; j< Rank;j++) {
     circle[i+(j*Rank)].check();
     circle[i+(j*Rank)].show(i * SqSide + SqSide/2, j*SqSide + SqSide /2);


   }
 }

}

class Circles{
 float x;
 float y;
 boolean circleON;

 Circles()  {
   circleON = true;
 }

 void ranCol() {


 }

 void check(){
   if (mousePressed == true) {

     if(dist(mouseX,mouseY,x,y)<=SqSide/2)circleON =  false;
   }
 }
 void show(float _x, float _y){
   x= _x;
   y= _y;

   float co;  
   co = random(5);
   int n;
   n = (int) co;
   if (n == 0) {
     fill (Green);
   }
   else {
     if (n == 1) {
       fill (Blue);
     }
     else {
       if (n == 2) {
         fill (Red);
       }
       else {
         if (n == 3) {
           fill (Yellow);
         }
         else {
           if (n == 4) {
             fill (White);
           }
           else {
             if (n == 5) {
               fill (Black);
             }
           }
         }
       }
     }
   }


   if(circleON){

     ellipse(x,y,SqSide,SqSide);
   }
 }
}

Wouldn't the cascading ifs be even clearer as a switch statement?
(Oops! just noticed PhiLho suggested this!  Here's the code anyway...)

Code:

n = (int) co;
switch(n) {
  case 0: 
     fill (Green);
    break;
  case 1: 
     fill (Blue);
    break;
  case 2: 
     fill (Red);
    break;
  case 3: 
     fill (Yellow);
    break;
  case 4: 
     fill (White);
    break;
  default: 
     fill (Black);
    break;
} 

I made some aditional changes by skipping all this if and else or switches and simply added a color array where you randomly pick one of the colors. Much shorter and easy to add more colors if you want...


Code:

int Rank = 12;
int SqSide = 20;
Circles[] circle = new Circles[Rank*Rank];
int Side = SqSide * Rank;
color[] colors = {#ff0000,#ffff00,#000000,#00ff00,#0000ff,#ffffff};

void setup() {
 size(Side, Side);
 smooth();
 background(#ffff00);  
 for (int i=0; i< circle.length;i++) {
   circle[i] = new Circles();
 }
}

void draw() {

 background(#ffff00);
 for (int i=0; i< Rank;i++) {
   for (int j=0; j< Rank;j++) {
     circle[i+(j*Rank)].check();
     circle[i+(j*Rank)].show(i * SqSide + SqSide/2, j*SqSide + SqSide /2);
  }
 }
}

class Circles{
 float x;
 float y;
 boolean circleON;

 Circles()  {
   circleON = true;
 }


 void check(){
   if (mousePressed == true) {

     if(dist(mouseX,mouseY,x,y)<=SqSide/2)circleON =  false;
   }
 }
 void show(float _x, float _y){
   x= _x;
   y= _y;

   fill(colors[int(random((colors.length)))]);

   if(circleON){

     ellipse(x,y,SqSide,SqSide);
   }
 }
}