Hi,

I am trying to make a piece of text or shape move randomly around the stage as if it has a life of its own. My big sleepy head hasn't been able to figure out this I would very much appreciate some help on how to do this. Apologies if I have missed another thread that answers this.

thats brownian motion too, but maybe its a better one for your purpose :


Wanderer[] wanderer = new Wanderer[1];

void setup()
{
 size(500, 500);
 background(50);
 fill(200);
 noStroke();
 
 for (int i=0; i<wanderer.length; i++)
 {
   wanderer[i] = new Wanderer(random(width), random(height));
 }
}

void draw()
{
 background(50);
 
 for (int i=0; i<wanderer.length; i++)
 {
   wanderer[i].stayInsideCanvas();
   wanderer[i].move();
   ellipse(wanderer[i].getX(), wanderer[i].getY(), 2, 2);
 }
}
class Wanderer
{
 float x;
 float y;
 float wander_theta;
 float wander_radius;
 
 // bigger = more edgier, hectic
 float max_wander_offset = 0.3;
 // bigger = faster turns
 float max_wander_radius = 3.5;
 
 Wanderer(float _x, float _y)
 {
   x = _x;
   y = _y;
   
   wander_theta = random(TWO_PI);
   wander_radius = random(max_wander_radius);
 }
 
 void stayInsideCanvas()
 {
   x %= width;
   y %= height;
 }
 
 void move()
 {
   float wander_offset = random(-max_wander_offset, max_wander_offset);
   wander_theta += wander_offset;
   
   x += cos(wander_theta);
   y += sin(wander_theta);
 }
 
 float getX()
 {
   return x;
 }
 
 float getY()
 {
   return y;
 }
}

IMHO, you'll get more aesthetic results from movement based on the noise() function:

http://processing.org/reference/noise_.html