check out http://smallbutdigital.com/themidibus.php

brand new contribution to processing.  i am a super newb, but this def looks like something that could possibly lead you in the right direction.

Hey beatkeepr,

I've looked into your question.

With relation to my library (themidibus), this is not really bug. It's quite common for MIDI hardware/software to use a noteOn with a velocity of 0 instead of a noteOff. In fact, the MIDI specification allows you to use them interchangeably (aka noteOn with vel 0 = noteOff). And currently themidibus gives you unaltered MIDI (so it doesn't do the NoteOn to NoteOff conversion for you).

It's fairly likely that your controller or some other part of your setup is sending noteOn with vel 0 instead of noteOff hence you get two noteOn messages instead of a noteOn and a noteOff message.

On the other hand, it would probably make sense for my library to do this conversion automatically because it's really common, especially in older MIDI hardware. I will try and fix this sometime later this afternoon when I have a bit of free time. I will update this thread and my main themidibus thread when I do so.

Also, I can confirm that when I use promidi I also get and extra noteOn after a slight delay. I poked around a bit, but I was in a hurry and couldn't figure out why at the moment. You should probably ask tex about that.

Hopefully this was helpful, I'll subscribe to this thread in case you have further problems/questions.

Here are some eclectic links that are useful/mention the noteOn vel 0 = noteOff behavior

http://www.srm.com/qtma/davidsmidispec.html (read the paragraph Note On, Note Off)

http://www.cycling74.com/forums/index.php?t=msg&th=36583&rid=0&S=901a1e8efaffef96e67f6f650d1bf083 (a flame war about it)

Sparky

Hello All,

As promised, this is the sketch I use to figure out what I'm receiving via the MidiBus library.  Any improvements are certainly welcome.

----Start of code----
/*
* This sketch is a simple diagnostic tool for monitoring MIDI
* input data. It uses the MidiBus library.
*
* Issues:
*/
import themidibus.*;

MidiBus myBus;

void setup(){

 // List all available Midi devices on STDOUT. This will show each device's index and name.
 MidiBus.list();
 myBus = new MidiBus(this, 0,1);
}

void draw(){
}

void noteOn(int channel, int pit, int vel){
 println(millis() + "\tNoteOn : Pitch=" + pit + "\tVelocity=" + vel + "\tChannel=" + channel);
}

void noteOff(int channel, int pit, int vel){
 println(millis() + "\tNoteOff: Pitch=" + pit + "\tVelocity=" + vel + "\tChannel=" + channel);
}

void controllerChange(int channel, int num, int val){
 println(millis() + "\tController Change: Number=" + num + "\tvalue=" + val + "\tChannel=" + channel);
}
----End of code----

Below is the equivalent using the proMIDI library. Note that it exhibits the behavior that I mentioned earlier in the thread. If anyone sees anything obvious that might be the cause, please let me know.

----Start of code----
/*
* This sketch is a simple diagnostic tool for monitoring MIDI
* input data. It uses the proMIDI library.
*/
import promidi.*;

MidiIO midiIO;

int device = 0;
// Roland TDW-1
// int channel = 8;
// Oxygen 8
int channel = 7;


void setup(){

 midiIO = MidiIO.getInstance(this);
 // print a list of all devices
 midiIO.printDevices();

 Receiver recvr = new Receiver();

 midiIO.plug(recvr,"noteOn", device, channel);
 midiIO.plug(recvr,"noteOff", device, channel);
 midiIO.plug(recvr,"controllerIn", device, channel);
 midiIO.plug(recvr,"programChange", device, channel);

}

// Note that without this draw function, nothing seems to happen!
void draw(){
}

// If this class is not declared public then it will cause the MidiIO.plug()
// method to fail with an IllegalAccessException.
public class Receiver {

 Receiver(){
   println("Created Receiver object recvr");
 }

 void noteOn(Note note){
   int vel = note.getVelocity();
   int pit = note.getPitch();
   println(millis() + "\tNoteOn : Pitch=" + pit + "\tVelocity=" + vel);
 }

 void noteOff(Note note){
   int pit = note.getPitch();
   int vel = note.getVelocity();

   println(millis() + "\tNoteOff: Pitch=" + pit + "\tVelocity=" + vel);
 }

 void controllerIn(Controller controller){
   int num = controller.getNumber();
   int val = controller.getValue();

   println(millis() + "\tController In: Number=" + num + "\tvalue=" + val);
 }

 void programChange(ProgramChange programChange){
   int num = programChange.getNumber();

   println(millis() + "\tProg Change: Number=" + num);
 }  
}// class Receiver
----End of code----

Hey Sparky,

Thanks for the mods, I'll fetch that when I can.  So far your library has been working very well for me.

As for the time stamp thing, thanks also for looking into it. I'm perfectly happy using millis() wherever I need to.  Yes, I suppose the object model could be richer and that might lead to better code, but it is not as if I couldn't fashion such an object model myself outside of the MidiBus. It's better to keep the common libs simple, no?

So far I've managed to determine the tempo based on noteOn events, but I haven't quite managed to make that influence frameRate() and/or other values or calculations.  (That's more about having time to complete it.  It's all about timing, isn't it?)

beatkeeper