No, you should definitely take advantage of classes.  The reason for this is because you can use inheritance and/or interface to drag different types of objects without re-implementing the algorithm for everything.

Try this.  A bit buggy, but I'm sure you can work out the rest:

Query myQuery1;

Boolean isDragging;
int dragX;
int dragY;

void setup()
{
 size(800, 500);
 smooth();
 myQuery1 = new Query(color(0,0,255),width/2.0,height/5.0,100,20);
}

void draw()
{
 background(0);
   myQuery1.display();
}



class Query {
 color qc;
 float qx;
 float qy;
 int dQx;
 int dQy;

 Query(color tempQc, float tempQx, float tempQy,int tempdQx, int tempdQy) {
   qc = tempQc;
  qx = tempQx;
  qy = tempQy;
  dQx = tempdQx;
  dQy = tempdQy;
 }

 void display() {
   background(0);
   stroke(0);
   fill(qc);
   rectMode(RADIUS);
   rect(qx,qy,dQx,dQy);
 }
 
 boolean inQuery(int x, int y){
   //btw, my code here is horrible.  Use Shape instead.  I was too lazy (sw01)
 
   if((x > qx) & x < (qx+dQx)){
     if((y > qy)  & y < (qy+dQy)){
       
       return true;
     }
   }
   return false;
 }
 
 
 
}

void mousePressed(){
 println("pressed");
 if (myQuery1.inQuery(mouseX, mouseY)){
   isDragging = true;
   dragX = (int)myQuery1.qx - mouseX;
   dragY = (int)myQuery1.qy - mouseY;
   
 }else{
   print("not in query");
   isDragging = false;
 }
}



void mouseReleased(){
 isDragging = false;
}


void mouseDragged(){
 println("dragging");
 if(isDragging){
   myQuery1.qx = mouseX + dragX;
   myQuery1.qy = mouseY + dragY;
 }
}

Yes, you are absolutely right that the dragging implementation is too specific.  However, with a little change, you can formalize and abstract the process.

Here's how using a class helps to organize your code.  One thing to note is how you can use the concept of "one hand" by using an object variable "queryBeingDragged" instead of using a Boolean variable.  A "null" object (a special singleton object pointing to nothing) in the variable represents an "empty hand."  Furthermore, the use of an array allows you to handle any number of Queries in your code.

By the way, how do you put that box around your code in your post?

code:


//////////////////////////////////////////////

import java.util.ArrayList;

ArrayList myQueries;

Query queryBeingDragged;


int dragX;
int dragY;

void setup()
{
 queryBeingDragged = null;
 myQueries = new ArrayList();
 
 size(800, 500);
 smooth();
 
 
 myQueries.add( new Query("myQuery1",color(0,0,255),width/2.0+100,height/5.0+100,100,20));
 myQueries.add( new Query("myQuery2", color(255,0,0),width/2.0,4.0*height/5.0,100,20));
 
 
}

void draw()
{
 background(0);
 
 for(int i = 0; i < myQueries.size(); i++){
   Query myQuery1 = (Query)myQueries.get(i);
   myQuery1.display();
 }
}



class Query {
 String name;
 
 color qc;
 float qx;
 float qy;
 int dQx;
 int dQy;

 Query(String name, color tempQc, float tempQx, float tempQy,int tempdQx, int tempdQy) {
  this.name = name;
   qc = tempQc;
  qx = tempQx;
  qy = tempQy;
  dQx = tempdQx;
  dQy = tempdQy;
 }

 void display() {
   //println("displaying" + name);
   //background(0);<=== ***this is why you only saw one box
   stroke(0);
   fill(qc);
   rectMode(RADIUS);
   rect(qx,qy,dQx,dQy);
 }
 
 boolean inQuery(int x, int y){
   //changed to x > qx-dQx and y > qy-dQy
   
   if((x > qx-dQx) & x < (qx+dQx)){
     if((y > qy-dQy)  & y < (qy+dQy)){
       
       return true;
     }
   }
   return false;
 }
 
 
 
}  

void mousePressed(){
 for(int i = 0; i < myQueries.size(); i++){
    // note how I made it generic
   
   Query myQuery1 = (Query)myQueries.get(i);
   evaluateQuerySelection(myQuery1);
 
 }
 println("pressed");
 
}

void evaluateQuerySelection(Query myQuery1){
 // note how absolutely lazy I was in just pasting the old code
if (myQuery1.inQuery(mouseX, mouseY) & queryBeingDragged==null){
   //note how it will not evaluate if something is already being dragged
 
   
   dragX = (int)myQuery1.qx - mouseX;
   dragY = (int)myQuery1.qy - mouseY;
   queryBeingDragged = myQuery1;
 
}

}



void mouseReleased(){
 queryBeingDragged = null;
}


void mouseDragged(){
 if( queryBeingDragged != null){
    println("dragging" + queryBeingDragged.name);
   moveQueryByMouse(queryBeingDragged);
  }
}  



void moveQueryByMouse(Query myQuery1){
 myQuery1.qx = mouseX + dragX;
 myQuery1.qy = mouseY + dragY;


}

Ah, I was hoping it'll come to that.  

This situation calls for inheritance: Both Query and Hit share very similar characteristics, so you can make a parent class that has those characteristics.  By using inheritance, the draw routine can handle both Hit and Query as a same category of objects.

Let's call it "abstractSearchObject".  Abstract because there is no real object that is both hit and a query, and can never be instantiated (you could, but it may not make sense).  Also, A query may or may not have a hit.  A line should be drawn from a Query to a Hit, but that is an extra feature that can be added to Query, but not for hit.

These statements are embodied in the code below.  It is not the most flexible code - but you can modify it to make it so (e.g., you can modify this code to have multiple hits per query using ArrayList).

Here's the code (thanks for the tip!):

Code:

import java.util.ArrayList;
 
ArrayList myQueries;

// Note how the "hand" no longer holds just Queries
abstractSearchObject queryBeingDragged;


int dragX;
int dragY;
 
void setup()
{
  queryBeingDragged = null;
  myQueries = new ArrayList();
  
  size(800, 500);
  smooth();
  
  Hit h1 = new Hit("myHit1",color(0,255, 0),width/2.0+100,height/5.0+50,100,20);
  Query q1 =  new Query("myQuery1",color(0,0,255),width/2.0+100,height/5.0+100,100,20);
  Query q2 =  new Query("myQuery2", color(255,0,0),width/2.0,4.0*height/5.0,100,20);
  

// here is where the q1 "connects" to h1
  q1.hit = h1; 
  
// note how I am stuffing everything into one array
  myQueries.add(h1 );
  myQueries.add(q1 );
  myQueries.add(q2 );
  
}
 
void draw()
{
  background(0);
  
  for(int i = 0; i < myQueries.size(); i++){

// note how I no longer assume it is only query that is being drawn.
    abstractSearchObject myQuery1 = (abstractSearchObject)myQueries.get(i);
    myQuery1.display();
  }
}
 
 
 
void mousePressed(){
  for(int i = 0; i < myQueries.size(); i++){ 
     // note how I made it generic 
    abstractSearchObject myQuery1 = (abstractSearchObject)myQueries.get(i);
    evaluateQuerySelection(myQuery1);
  }
  println("pressed");
  
}

void mouseReleased(){
  queryBeingDragged = null; 
} 
 
void mouseDragged(){
  if( queryBeingDragged != null){
     println("dragging" + queryBeingDragged.name);
    //moveQueryByMouse(queryBeingDragged);
    // note how I encapsulated the movement from directly affecting qx and qy
    queryBeingDragged.moveByMouseCoord(mouseX, mouseY);
   }
}  




void evaluateQuerySelection(abstractSearchObject myQuery1){ 
  if (myQuery1.inQuery(mouseX, mouseY) & queryBeingDragged==null){ 
    dragX = (int)myQuery1.qx - mouseX;
    dragY = (int)myQuery1.qy - mouseY;
    queryBeingDragged = myQuery1;
  }
}



// This is how to use inheritance.  Use interface instead if you want even more flexibility.
abstract class abstractSearchObject{
  String name;
  
  color qc;
  float qx;
  float qy;
  int dQx;
  int dQy;
 
  abstractSearchObject(String name, color tempQc, float tempQx, float tempQy,int tempdQx, int tempdQy) {
    this.name = name;
     qc = tempQc;
     qx = tempQx;
     qy = tempQy;
     dQx = tempdQx;
     dQy = tempdQy;
  }
 
  void display() {
    stroke(0);
    fill(qc);
    rectMode(RADIUS);
    rect(qx,qy,dQx,dQy);
  }
  
  boolean inQuery(int x, int y){
    if((x > qx-dQx) & x < (qx+dQx)){
      if((y > qy-dQy)  & y < (qy+dQy)){
        
        return true;
      }
    }
    return false;
  }
  
  void moveByMouseCoord(int mausX, int mausY){
    this.qx = mausX + dragX;
    this.qy = mausY + dragY;
  }
}


// "extends" is what makes inheritance happen.
class Query extends abstractSearchObject{
  
  Hit hit = null;
  
  Query(String name, color tempQc, float tempQx, float tempQy,int tempdQx, int tempdQy) {
// by convention, you cannot inherit the constructor.
    super( name,  tempQc,  tempQx,  tempQy, tempdQx,  tempdQy);
  }
  
  void display(){
//super is the keyword to refer to the parent class.
        super.display();  // see how I'm calling the parent class's draw routine
    if(hit != null){
    // Draw the connector line

stroke(255);
    line(this.qx,this.qy, hit.qx, hit.qy);
    
    }
  
  }
  
  
}


class Hit extends abstractSearchObject{
  
  Hit(String name, color tempQc, float tempQx, float tempQy,int tempdQx, int tempdQy) {
    super( name,  tempQc,  tempQx,  tempQy, tempdQx,  tempdQy);
  }
}


 

Yes, this is where oop shines.  

You've already taken the right step in creating the "Connect" object.  Now all that needs to be done is for the Query to handle that connect objects instead of directly dealing with hit.


Code:

import java.util.ArrayList;
 
ArrayList myQueries;

abstractSearchObject queryBeingDragged;


int dragX;
int dragY;
 
void setup()
{
  queryBeingDragged = null;
  myQueries = new ArrayList();
  
  size(800, 500);
  smooth();
  
  Hit h1 = new Hit("myQuery1",color(0,255, 0),width/2.0+100,height/5.0+50,100,20);
  Query q1 =  new Query("myQuery1",color(0,0,255),width/2.0+100,height/5.0+100,100,20);
  Query q2 =  new Query("myQuery2", color(255,0,0),width/2.0,4.0*height/5.0,100,20);
  
  
  
  //q1.hit = h1; 
  //myConnect1 = new Connect(color(255,0,0),width/2.0,height/5.0,width/2.0,4.0*height/5.0,+32 ,-57);
  q1.addHitLink("myConnect1", color(255,0,0), h1,+32 ,-57);
  //myConnect2 = new Connect(color(255,255,50),width/2.0,height/5.0,width/2.0,4.0*height/5.0, +30,+50);
  q1.addHitLink("myConnect2", color(255,255,50), h1, +30,+50);
  //myConnect3 = new Connect(color(0,255,50),width/2.0,height/5.0,width/2.0,4.0*height/5.0,-64,+59);
  q1.addHitLink("myConnect1", color(0, 255,50), h1,-64,+59);
  
  
  myQueries.add(h1 );
  myQueries.add(q1 );
  myQueries.add(q2 );
  
}
 
void draw()
{
  background(0);
  
  for(int i = 0; i < myQueries.size(); i++){
    abstractSearchObject myQuery1 = (abstractSearchObject)myQueries.get(i);
    myQuery1.display();
  }
}
 
 
 
void mousePressed(){
  for(int i = 0; i < myQueries.size(); i++){ 
     // note how I made it generic 
    abstractSearchObject myQuery1 = (abstractSearchObject)myQueries.get(i);
    evaluateQuerySelection(myQuery1);
  }
  println("pressed");
  
}

void mouseReleased(){
  queryBeingDragged = null; 
} 
 
void mouseDragged(){
  if( queryBeingDragged != null){
     println("dragging" + queryBeingDragged.name);
    queryBeingDragged.moveByMouseCoord(mouseX, mouseY);
   }
}  




void evaluateQuerySelection(abstractSearchObject myQuery1){ 
  if (myQuery1.inQuery(mouseX, mouseY) & queryBeingDragged==null){ 
    dragX = (int)myQuery1.qx - mouseX;
    dragY = (int)myQuery1.qy - mouseY;
    queryBeingDragged = myQuery1;
  }
}



// This is how to use inheritance.  Use interface instead if you want even more flexibility.
abstract class abstractSearchObject{
  String name;
  
  color qc;
  float qx;
  float qy;
  int dQx;
  int dQy;
 
  abstractSearchObject(String name, color tempQc, float tempQx, float tempQy,int tempdQx, int tempdQy) {
    this.name = name;
     qc = tempQc;
     qx = tempQx;
     qy = tempQy;
     dQx = tempdQx;
     dQy = tempdQy;
  }
 
  void display() {
    stroke(0);
    fill(qc);
    rectMode(RADIUS);
    rect(qx,qy,dQx,dQy);
  }
  
  boolean inQuery(int x, int y){
    if((x > qx-dQx) & x < (qx+dQx)){
	if((y > qy-dQy)  & y < (qy+dQy)){
	  
	  return true;
	}
    }
    return false;
  }
  
  void moveByMouseCoord(int mausX, int mausY){
    this.qx = mausX + dragX;
    this.qy = mausY + dragY;
  }
}



class Query extends abstractSearchObject{
  
  //Hit hit = null;
  ArrayList connects = new ArrayList();
  
  
  Query(String name, color tempQc, float tempQx, float tempQy,int tempdQx, int tempdQy) {
    super( name,  tempQc,  tempQx,  tempQy, tempdQx,  tempdQy);
  }
  
  void display(){
    super.display();  // see how I'm calling the parent class's draw routine
    
    for(int i=0; i < connects.size(); i++){
	Connect connect = (Connect)connects.get(i);
	connect.display();
    }
  }
  
  
  void addHitLink(String connectName, color cc, Hit hit, int connector_qry_offset, int connector_hit_offset ){
    Connect connect = new Connect(connectName, cc,  this, hit, connector_qry_offset, connector_hit_offset);
    connects.add(connect);
  }
  
}


class Hit extends abstractSearchObject{
  
  Hit(String name, color tempQc, float tempQx, float tempQy,int tempdQx, int tempdQy) {
    super( name,  tempQc,  tempQx,  tempQy, tempdQx,  tempdQy);
  }
  
}


//Connector Class Creation
class Connect {
  color cc;
  
  String name;
  
  Query query = null;
  Hit hit = null;
  //float qx;
  //...
 // offsets to define "alignment mapping" line
  int connector_qry_offset;
  int connector_hit_offset;
 
 
  Connect(String name, color tempCc, Query query, Hit hit, int tempconnector_qry_offset, int tempconnector_hit_offset) {
    this.name = name;
    cc = tempCc;
    this.query = query;
    this.hit = hit;
    
   //Note how hit and query replaces the lines below - the objects already contain the data
   //qx = tempQx;
   //...
   connector_qry_offset = tempconnector_qry_offset;
   connector_hit_offset = tempconnector_hit_offset;
  }
 
  void display() {
    stroke(cc);
    // this is where the data from query and hit objects are used.
    line(query.qx + connector_qry_offset, query.qy, hit.qx + connector_hit_offset, hit.qy);
  }
}