final int NLINHAS = 80; //number of lines
final int COMPINI = 10; //initial length
final int VARCOMP = 20; //length variation
final int LARG = 300;
final int ALTU = 300;
//caculate the center coordenates
final int XC = LARG / 2;
final int YC = ALTU/ 2;


// NEW STUFF - START ***
int cLine = 0; // The current line
int timeBetweenAddedLines = 30; // milliseconds;
int lastLineTime = 0; // time last line was added
float[] strokes; // array of strokeWeights
float minStroke = 1; // minimum strokeweight if randomStrokes = true
float maxStroke = 5; // maxiumu strokeweight if randomStrokes = true
float distDiv = 50; // Distance divider;
boolean randomStrokes = false; // set to true if you want random strokeweights between minStroke and maxStroke. when set to false, it uses length of the line, divided by distDiv
// NEW STUFF - END ***
 
void setup() {
  background(255);
  size (LARG, ALTU);
  stroke (100);
  strokeWeight (1);
  smooth(); // to get that nice antialiasing
  // noLoop(); *** commented out this line, because it forces the draw to only run once
  frameRate (20);
  strokes = new float[NLINHAS]; // ***
}
   
void draw() {
  // initialize the variables every frame
  int xFim, yFim; //line extremity coordenates
  int comp = COMPINI; //line length
  int varComp = VARCOMP; //length variation
  float angulo = 0; //current angle 
  float varang = (float)(2 * PI / NLINHAS); //calculate the angle increment in radians

  // clear background ***
  background(255); // ***
  
  // increment lines ***
  if(cLine < NLINHAS && lastLineTime+timeBetweenAddedLines < millis()) //  ***
  { //  ***
    strokes[cLine] = random(minStroke,maxStroke); //  ***
    cLine++; // Increment one to start with, or else, it won't draw  ***
    lastLineTime = millis(); // ***
  } //  ***
  
  //draw the lines
  for (int linha=0; linha < cLine; linha++){
    //calculate the end of the line (xFim, yFim)
    xFim = XC + (int)(comp * cos(angulo));
    yFim = YC - (int)(comp * sin(angulo));
    //verify if (xFim, yFim) is outside of the applet or if the length is negative
    //if it is reduce the length, then the
    //length decreses amd calculate the new point
    if (xFim>LARG || yFim>ALTU || xFim<0 || yFim<0 || comp <0) {
	varComp *= -1;
	comp += 2*varComp;
	xFim = XC + (int)(comp * cos(angulo));
	yFim = YC - (int)(comp * sin(angulo));
    }
    // set the strokeWeight ***
    if(randomStrokes){
	strokeWeight(strokes[linha]); //  ***
    }else{
	strokeWeight(dist(XC, YC, xFim, yFim)/distDiv); //  ***
    }
    //draw the line
    line(XC, YC, xFim, yFim);
    //update the length
    comp += varComp;
    //update the angle
    angulo += varang;
  }
}