Hi all,

I have just started using processing, and am using Ben Fry's"Visualizing Data" book to get to grips with it. However, I am getting an error despite copying the example coding. The program is attempting to map data to an outline of the US.

I am getting the error 'cannot find a class or type named "Table"'

There is probably something blatantly obvious in the code, can anyone help, code below:


PImage mapImage;
Table locationTable;
int rowCount;
Table dataTable;
float dataMin = MAX_FLOAT;
float dataMax = MIN_FLOAT;

void setup() {
 size(640, 400);
 mapImage = loadImage("map.png");
 locationTable = new Table("locations.tsv");
 rowCount = locationTable.getRowCount();
 
 //Read the data table.
 dataTable = new Table("random.tsv");
 
 // Find the minimum and maximum values.
 for (int row = 0; row < rowCount; row++) {
   float value = dataTable.getFloat(row, 1);
   if (value > dataMax) {
     dataMax = value;
   }
   if (value < dataMin) {
     dataMin = value;
   }
 }
}
void draw() {
 background(255);
 image(mapImage, 0, 0);
 
 // Drawing attributes for the ellipses.
 smooth();
 fill(192, 0, 0);
 noStroke();
 for (int row = 0; row < rowCount; row++) {
   String abbrev = dataTable.getRowName(row);
   float x = locationTable.getFloat(abbrev, 1);
   float y = locationTable.getFloat(abbrev, 2);
   drawData(x, y, abbrev);
 }
}

// Map the size of the ellipse to the data value
void drawData(float x, float y, String abbrev) {
 //Get data value for state
 float value = dataTable.getFloat(abbrev, 1);
 // Re-map the value to a number between 2 and 40
 float mapped = map(value, dataMin, dataMax, 2, 40);
 // Draw an ellipse for this item
 ellipse(x, y, mapped, mapped);
}
   //Loop through the rows of the locations file and draw the points.
 for (int row = 0; row < rowCount; row++) {
   float x = locationTable.getFloat(row, 1);  // column 1
   float y = locationTable.getFloat(row, 2);  // column 2
   ellipse(x, y, 9, 9);
 }
}
class Table {
 String[][] data;
 int rowCount;
 
 
 Table() {
   data = new String[10][10];
 }

 
 Table(String filename) {
   String[] rows = loadStrings(filename);
   data = new String[rows.length][];
   
   for (int i = 0; i < rows.length; i++) {
     if (trim(rows[i]).length() == 0) {
       continue; // skip empty rows
     }
     if (rows[i].startsWith("#")) {
       continue;  // skip comment lines
     }
     
     // split the row on the tabs
     String[] pieces = split(rows[i], TAB);
     // copy to the table array
     data[rowCount] = pieces;
     rowCount++;
     
     // this could be done in one fell swoop via:
     //data[rowCount++] = split(rows[i], TAB);
   }
   // resize the 'data' array as necessary
   data = (String[][]) subset(data, 0, rowCount);
 }


 int getRowCount() {
   return rowCount;
 }
 
 
 // find a row by its name, returns -1 if no row found
 int getRowIndex(String name) {
   for (int i = 0; i < rowCount; i++) {
     if (data[i][0].equals(name)) {
       return i;
     }
   }
   println("No row named '" + name + "' was found");
   return -1;
 }
 
 
 String getRowName(int row) {
   return getString(row, 0);
 }


 String getString(int rowIndex, int column) {
   return data[rowIndex][column];
 }

 
 String getString(String rowName, int column) {
   return getString(getRowIndex(rowName), column);
 }

 
 int getInt(String rowName, int column) {
   return parseInt(getString(rowName, column));
 }

 
 int getInt(int rowIndex, int column) {
   return parseInt(getString(rowIndex, column));
 }

 
 float getFloat(String rowName, int column) {
   return parseFloat(getString(rowName, column));
 }

 
 float getFloat(int rowIndex, int column) {
   return parseFloat(getString(rowIndex, column));
 }
 
 
 void setRowName(int row, String what) {
   data[row][0] = what;
 }


 void setString(int rowIndex, int column, String what) {
   data[rowIndex][column] = what;
 }

 
 void setString(String rowName, int column, String what) {
   int rowIndex = getRowIndex(rowName);
   data[rowIndex][column] = what;
 }

 
 void setInt(int rowIndex, int column, int what) {
   data[rowIndex][column] = str(what);
 }

 
 void setInt(String rowName, int column, int what) {
   int rowIndex = getRowIndex(rowName);
   data[rowIndex][column] = str(what);
 }

 
 void setFloat(int rowIndex, int column, float what) {
   data[rowIndex][column] = str(what);
 }


 void setFloat(String rowName, int column, float what) {
   int rowIndex = getRowIndex(rowName);
   data[rowIndex][column] = str(what);
 }
 
 
 // Write this table as a TSV file
 void write(PrintWriter writer) {
   for (int i = 0; i < rowCount; i++) {
     for (int j = 0; j < data[i].length; j++) {
       if (j != 0) {
         writer.print(TAB);
       }
       if (data[i][j] != null) {
         writer.print(data[i][j]);
       }
     }
     writer.println();
   }
   writer.flush();
 }
}

no, he specifies the Table class in the code example

Code:

class Table {
...
 

the problem is in the block of code immediately above it - it seems to be missing a line. the brace after the ellipse() matches the one at the start of the method which leaves everything after it orphaned. there needs to be a method declaration on the line below it.

Code:

// Map the size of the ellipse to the data value
void drawData(float x, float y, String abbrev) {
  //Get data value for state
  float value = dataTable.getFloat(abbrev, 1);
  // Re-map the value to a number between 2 and 40
  float mapped = map(value, dataMin, dataMax, 2, 40);
  // Draw an ellipse for this item
  ellipse(x, y, mapped, mapped);
}
    //Loop through the rows of the locations file and draw the points.
  for (int row = 0; row < rowCount; row++) {
    float x = locationTable.getFloat(row, 1);  // column 1
    float y = locationTable.getFloat(row, 2);  // column 2
    ellipse(x, y, 9, 9);
  }
}
 

how can we know what's missing? it could be anything.

i've commented it out and it compiles (which suggests that nothing in the remaining code is looking for a missing function) but given that i don't have map.png or locations.tsv i can't actually run it.

Code:

/*
    //Loop through the rows of the locations file and draw the points.
  for (int row = 0; row < rowCount; row++) {
    float x = locationTable.getFloat(row, 1);  // column 1
    float y = locationTable.getFloat(row, 2);  // column 2
    ellipse(x, y, 9, 9);
  }
}
*/
 

official errata here:
http://oreilly.com/catalog/9780596514556/errata/
but a quick scan shows nothing (but, again, not knowing page number or example name...)

also there's a board here for bugs in the book:
http://processing.org/discourse/yabb_beta/YaBB.cgi?board=WebsiteBugs

(edit, added board link)

I too am working through the examples in Visualizing Data.  

When I was putting mine together, I added the Table class as a separate file.  It looks like you added all of the code for the class at the bottom of your project.  You may want to try taking the code for the Table class out of your project.  After you do that, download the Table class or swipe it from one of the example projects and use Sketch>add File to add it back to your project.  

I was frustrated with adding the Table class too, but did get my map to work.

Looking at one of the example projects from the link that Fry posted will give you an idea of what the pieces will look like once you put them together.  

Good Luck!

Hi all,

If there are things that are confusing (or incorrect, for that matter), please let me know--I'd much rather hear what's going wrong and get things fixed for later editions of the book. If you find errors in the book, please feel free to use O'Reilly's online errata system:
http://oreilly.com/catalog/9780596514556/errata/
Or send me email directly (address in on my site) for other issues.

which example is it?

check here (there could be a typesetting error):
http://benfry.com/writing/archives/3