Hi folks,

What I would like to do is to be able to get draw to reach a predefined point and then stop and wait for input from me (a mouse press for example) before proceeding.

I tried to do it with the following test code but all I get is a blank screen and no output. PS - this code also sends the Java window off to never-never land
Code:

int loopEnd=1000;
boolean wait4mouse=true;
int strokC=0;
void setup(){
  size(400,400);
  background(255); strokeWeight(2); smooth();
  stroke(strokC);
} // end setup


void draw() {
  for(int i=1; i < loopEnd; i++) {
    ellipse(random(0,width),random(0,height),4,4);
  } // end loop

while(wait4mouse) { 
  if (mousePressed == true) {
    strokC+=5;
    stroke(strokC);
    background(255); 
    println("****** NEW SCREEN ******");
    wait4mouse=false;
    } // end mousepressed
 } // end wait4mouse loop
 
 wait4mouse=true;
} // end draw  
 

I click in the window repeatedly but nothing happens.

I also tried doing this using the mousePressed() method.

So what am I missing here?

Thanks.

Jim

There's also a nifty little function called delay(), which takes and int of milliseconds for how long it should wait before drawing the next screen.
Also, by setting the while loop and having an if(mousePressed), you're basically waiting each frame for the mouse to be pressed... which isn't a good idea

you might as well just draw a blank screen.. and if the mouse is pressed, draw something..

-seltar

Hi Stephen,

Thank you for your response. In reply to your questions:

Q1)do you want the same thing drawn each time the sketch runs or are you happy to have random things drawn?

A1) No, within either a mousepressed loop or mousepressed() method, once I press the button I want to load in new parameters and then redraw using those values.  The code I provided here is just a skeleton to see if I could get the basic process down.

Q2) background() must be called each time the draw method is called if you want the screen to be redrawn.

A2) I do want the screen redrawn anew for each set of parameters.  

Q3)  This will draw 1000 random ellipses before the following lines are reached, and this is expected to happen 60 times a second. Is this what you want?

A3) I want draw to execute the statements contained within the loop exactly one time (for the example to draw 1000 ellipses) and then just stop and do nothing further until I press the mouse button. Only once I've pressed the button (and load new values as a consequence) do I want draw() to start drawing again.

Q4)  I try to avoid for and while loops in the draw that could potentially freeze everything.

A4) Not what I was hoping to hear.

Q5) Here is a reworked version of the code you posted:

A5) The problem with your code is you have no control over how many things are drawn (ellipses in this case). That is the control that I need. I want draw() to draw exactly N things and then stop and wait for me to tell it to proceed.

As to anything being drawn on the screen, I just get a blank screen and Java hangs. Also putting the mouse checking code before the drawing statements makes no difference: nothing gets drawn, the print message doesn't print after a mouse click, and I have to close down all open processing windows to get the java window to close.

I fear that I am going to have to abandon this approach and rely on a mouse click to swap to the noloop mode and then a key press to load the new parms and then another mouse click to go back into loop mode.

Thanks Stephen.

Hi Jim,

This version doesn't support animation, but it seems to do mostly what you want. It is late here, so I may have misread what you need. It should draw n items once. Then wait until a mouse press. Then redraw once with a new set of params (in this case a single random, but easy to change). It clears the screen every draw. Again, this won't look animated, it draws and then displays a single frame. I could make an animated version if you need it (so each ellipse appears in turn) but it is messier.

Code:

int numberToDraw = 0;
void setup()
{
  size(400,400);
  strokeWeight(2); 
  smooth();
  numberToDraw = (int)random(100);
}
 
void draw() 
{
  background(255);
  for(int i = 0; i < numberToDraw; i++)
  {
    stroke(random(255), random(255), random(255));  
    ellipse(random(0,width),random(0,height),4,4);
  }
  noLoop();
} 

void mousePressed()
{
   //load new parameters here...
   numberToDraw = (int)random(100);
   redraw();
}
 

Regards,

Stephen

No problems, send us a link to your final sketch if you can!

Stephen