I can be wrong, but I believe Processing always handles the main graphic area with some background, explicit or implicit.

I managed to save with transparency only when drawing on an off-screen PGraphics area. To recycle a previous example (which was an answer to how to clip a drawing area to a sub-area of the display):

PGraphics drawingArea;
int DA_X = 50, DA_Y = 10;
int DA_WIDTH = 200, DA_HEIGHT = 200;

void setup()
{
 size(300, 300);
 smooth();
 // Create a new graphical context
 drawingArea = createGraphics(DA_WIDTH, DA_HEIGHT, JAVA2D);
 drawingArea.beginDraw();
 drawingArea.background(0, 0); // Black with transparency
 drawingArea.endDraw();
}

void draw()
{
 background(#AAFFBB);
 // Update display
 image(drawingArea, DA_X, DA_Y);
}

void mousePressed()
{
 if (mouseX < DA_X || mouseX >= DA_X + DA_WIDTH || mouseY < DA_Y || mouseY >= DA_Y + DA_HEIGHT)
   return;
 drawingArea.beginDraw();
 drawingArea.ellipse(mouseX - DA_X, mouseY - DA_Y, 5 + random(20), 5 + random(20));
 drawingArea.endDraw();
}

void keyPressed()
{
 drawingArea.save("D:/temp/foo.png");
}