// global variables
float skalierung = 0.5;
Tree tree;

// setup
void setup() {
 size(800, 650);
 smooth();
 frameRate(10);
 tree = new Tree();
}

// main loop
void draw() {
 scale(skalierung);
 background(255);
 tree.grow();
 tree.display();
}

// the tree will be created on this model
class Tree {
 
 Branch[] branches; // tree has branches
 
 // constructor (called when a new tree is created)
 Tree() {
  branches = new Branch[1]; // that new tree will have one branch
  branches[0] = new Branch(400, 1300, -15, 50, 8, 30, 30); // create the (first and only) branch
 }
 
 // that tree can grow (make each branch grow)
 void grow() {
  for (int i = 0; i < branches.length; i++) {
   branches[i].grow();
  }
 }
 
 // that tree can be displayed on screen (display each branch)
 void display() {
  for (int i = 0; i < branches.length; i++) {
   branches[i].display();
  }
 }
 
}

// all branches will be created on this model
class Branch {
 
 Leaf[] leaves;
 int ageMax; // maximum number of leaves
 int blattDistance; // Distance between the steps
 float randomLeft; // tendencies to the left or right
 float randomRight;
 float stammWeight;
 int xx; //Starting Point
 int yy;
 int organic;
 int vzw=-1;
 int age=-1; //Startnummer (kind of 'age' of the branch)
 
 // constructor method, called when you create a new branch
 Branch(int _xx, int _yy, int _randomLeft, int _randomRight, int _stammWeight, int _ageMax, int _blattDistance) {
  xx = _xx;
  yy = _yy;
  randomLeft = _randomLeft;
  randomRight = _randomRight;
  stammWeight = _stammWeight;
  ageMax = _ageMax;
  blattDistance = _blattDistance;
  leaves = new Leaf[0];
 }
 
 // method you call to make the branch grow
 void grow() {
  if (age++ >= ageMax) return; // increase i and test if > max leaves
  organic = organic + int(random(randomLeft,randomRight)); //tendencies to the left or right
  vzw=vzw*-1; //change of sign to turn the leaf from left to right with every step
  leaves = (Leaf[])append(leaves, new Leaf(xx+organic, yy-age*blattDistance, vzw));
 }
 
 // method you call to draw the branch onto the screen
 void display() {
  
  // draw the branch itself
  if (age > 0) {
   line(xx, yy, leaves[0].x, leaves[0].y);
   for (int i = 1; i < leaves.length; i++) {
    stroke(0); strokeWeight(ageMax-i);
    line(leaves[i].x, leaves[i].y, leaves[i-1].x, leaves[i-1].y);
   }
   // draw each leaf
   for (int i = 0; i < leaves.length; i++) {
    leaves[i].display();
   }
  }
  
 }
 
}

class Leaf {
 
 int x, y; // position (Ast)
 int vzw; // orientation (left/right);
 int blattX, blattY;
 
 // constructor
 Leaf(int _x, int _y, int _vzw) {
  x = _x;
  y = _y;
  vzw = _vzw;
  blattX = int(x + vzw*random(30,50));
  blattY = int(y - random(20));
 }
 
 void display() {
  stroke(#39302C); strokeWeight(1);
  line(x, y, blattX, blattY);
  noStroke(); fill(0,255,0);
  ellipse(blattX, blattY, 20, 20);
 }
 
}