Normally, you could simply override the print() method to add file output. But in PApplet it's declared as static, so you will have to make your own print() and println() commands and use those instead.

To keep it simple, just make two methods that take Strings as parameters. Just make sure everything you want to print is turned into a String by adding "" to it. The following example works as is:

Code:

PrintWriter output;
boolean outputIsOn=true;

public void setup() {
  noLoop();
}

void myPrintln(String s) {
  if (outputIsOn) output.println(s);
  println(s);
}

void myPrint(String s) {
  if (outputIsOn) output.print(s);
  print(s);
}

public void draw() {
  output=createWriter(dataPath("logfile.txt"));

  float num2=10;
  float num3=3;
  
  myPrint(""+sin(num2)); // convert number to string
  myPrintln(" square("+num3+") = "+(num3*num3));

  output.close();
} 

FWIW I usually use the Java Logging API for such stuff. It's very easy to use and you can make use of the different log levels to adjust the granularity of your outputs. The other good thing is that you can see which method did the logging call, a very helpful detail for debugging without an actual debugger...

Code:

import java.util.logging.*;

Logger logger;

/**
 * Creates and initializes a new logger instance.
 * @param file absolut path/pattern to log file
 * @param level minimum log level to consider
 * (use level "ALL" for all messages)
 *
 * See for more info/examles:
 * http://www.exampledepot.com/egs/java.util.logging/pkg.html
 */
void initLogger(String file,String level) {
  try {
    // create a single log file and append to it if possible
    FileHandler fh=new FileHandler(file,true);
    fh.setFormatter(new SimpleFormatter());
    logger = Logger.getLogger("myloggername");
    logger.addHandler(fh);
    logger.setLevel(Level.parse(level));
    logger.info("logger started...");
  }
  catch(IOException e) {
    e.printStackTrace();
  }
}