LoadingThread lt;
int progressBarValue = 0;

void setup() {
 size(300, 200);
 lt = new LoadingThread();
 lt.start();
}

void draw() {
 if (lt.isAlive()) {
   background(255);
   int progressBarValue = int(lt.completed*(width-40));
   noStroke(); fill(250, 150, 0); rect(20, height*0.5-10, progressBarValue, 20);
   stroke(0); noFill(); rect(20, height*0.5-10, width-40, 20);
 } else {
   image(lt.img, 0, 0, width, height);
 }
}

class LoadingThread extends Thread {
 float completed = 0.0;
 PImage img;
 void run() {
   String url = "http://n.clavaud.free.fr/blog/images/gdbassin_case_creole_1024.jpg";
   int fileLen = 0;
   try {
     java.net.URL u = new java.net.URL(url);
     java.net.URLConnection uc = u.openConnection();
     fileLen = uc.getContentLength();
   } catch (java.net.MalformedURLException e) {
     println(e.getMessage());
     stop();
   } catch (java.io.IOException e) {
     println(e.getMessage());
     stop();
   }
   InputStream is = openStream(url);
   BufferedInputStream bis = new BufferedInputStream(is);
   ByteArrayOutputStream out = new ByteArrayOutputStream();    
   try {
     int c = bis.read();
     int bytesRead = 0;
     while (c != -1) {
       out.write(c);
       c = bis.read();
       bytesRead++;
       completed = (float)bytesRead/(float)fileLen;
     }
   } catch (java.io.IOException e) {
     println(e.getMessage());
   }
   byte[] bytes = out.toByteArray();
   Image awtImage = Toolkit.getDefaultToolkit().createImage(bytes);
   img = loadImageSync(awtImage);
 }
}