hi jaylfk,
try to use the code below for your sender.
i put the initialization of your oscMessage into setup, after oscP5 is initialized.
i also put the "Hello World" string into setup, otherwise your oscMessage would just be filled up with this string non stop after each draw update. i tried the code here, works fine. i didnt check in detail where this error originates from, so i guess it has to do with the moment of initializing the OscMessage.

Code:

 import oscP5.*;
import netP5.*;
 
OscP5 oscP5;
NetAddress myRemoteLocation; 
OscMessage myMessage;

void setup() {
  size(100, 100);
  frameRate(25);
  oscP5 = new OscP5(this,12000);
  myRemoteLocation = new NetAddress("127.0.0.1",12001);
  myMessage = new OscMessage("/Computer1"); 
  myMessage.add("Hello World");
}
				
void draw() {
 oscP5.send(myMessage, myRemoteLocation);    
}
 

the receiving part is fine, you may also try the plug method of oscP5 to get around the parsing in oscEvent e.g.

Code:

import oscP5.*;
import netP5.*;
 
OscP5 oscP5;
 
void setup() {
  size(100,100);
  frameRate(25);
  oscP5 = new OscP5(this,12001);
  oscP5.plug(this,"incoming","/Computer1");
}
 

void incoming(String theString) {
  println("i got a string, "+theString);
}
 

regarding the boostrap_register message, this link may give you an answer (this doesnt just apply to eclipse but also any other java app)

andi

the bootstrap error is covered in the reference:
http://processing.org/reference/environment/platforms.html#mac
it's an apple bug.

Thank you very much !

You made it real clear.
I finally get it to work as i wanted to.

UdpClient.send ioexception indicates that you are sending OSC messages via the UDP protocol. the error occurs if you try to send too many bytes to a remote machine that is not capable of handling the amount of sent bytes. in this case the server, remote machine, needs to increase its datagram size.
UDP in general is able to handle 64k bytes per packet. an OSC message (excluding address pattern) with 1000 ints would be
1000*4 bytes(ints) + 1000*1 byte (typetag) = 5000 bytes

so in order to receive 1000 ints with e.g. oscP5, the datagramsize, which is 1536 bytes by default for oscP5, would need to be increased to (to be save) 5400 bytes.

how to do that see the oscP5properties example that comes with oscP5, or is available on the website.

the UdpServer.run ArrayOutOfBoundsException occurs for same reasons, increase the datagramsize and you should be fine.

maybe also keep in mind that OSC is considered to be a control message protocol, meaning only values to control something should be transmitted over a network and you should avoid to use the protocol to exchange huge packets of data e.g. sound or video streaming, fft, blob detection. try to make as many calulations inside of an application and only distributed the results that will be explicitly useful on the remote machines. this will keep the network communication efficient and little.

Hi again,

I tried this in receiver's setup() but still stuck with the same error.

Quote:


Any idea why it doesn't work ?

hi, maybe the server/client code below might help.
in your code you create 2 instances of oscP5, each for a different address pattern, listening on different ports. you dont necessarily need to do that, you can only run 1 instance of oscP5 and use the addressPattern as identifier instead of the port - which you are already doing in oscEvent. so no need for 2 instances.
In your sender (client) code you are sending one message for each iteration of your loop which is quite inefficient, rather consider to create an empty osc message before starting the loop, with each iteration of your loop, add a new value to that message, after the loop is finished, send/flush the message.
to receive an array of ints (or floats or Strings) on the server side, use oscP5.plug which will instruct oscP5 to forward incoming messages directly to a dedicated function inside your sketch - instead of going through oscEvent (see Server example below). maybe the client and server code below makes things easier for you. run both sketches at a time and use key 1 and 2 in the client sketch so send a bunch of ints to the server sketch.
best,
andreas

Code:

/**
 * OSC server, waiting for incoming messages on port 5500
 */
 
import oscP5.*;
import netP5.*;
  
OscP5 oscP5;

void setup() {
  size(400,400);
  frameRate(25);
  OscProperties props = new OscProperties();
  // increase the default datagram size used by oscP5
  // because we are receiving a lot of values at a time.
  props.setDatagramSize(4096); 
  // set the listening port for oscP5
  props.setListeningPort(5500);
  // initialize oscP5
  oscP5 = new OscP5(this,props);
  
  // use oscP5's plug method to link incoming 
  // osc messages with functions included in your sketch.
  // in the following, incoming messages with address pattern
  // /X and /Y will be forwarded to positionX() and positionY()
  oscP5.plug(this, "positionX","/X");
  oscP5.plug(this, "positionY","/Y");
  
  background(0);  
}

// positionX will be called by oscP5 when receiving
// an OSC message with address pattern /X (see plug above)
// the OSC arguments must be of type int
void positionX(int[] theValues) {
  println("X: "+theValues.length);
  for(int i=0;i<theValues.length;i++) {
    stroke(theValues[i]);
    line(0,i,width,i);
  }
}

// positionX will be called by oscP5 when receiving
// an OSC message with address pattern /Y (see plug above)
// the OSC arguments must be of type int

void positionY(int[] theValues) {
  println("Y: "+theValues.length);
  for(int i=0;i<theValues.length;i++) {
    stroke(theValues[i]);
    line(i,0,i,height);
  }
}


void draw() {
}
 

Code:

/**
 * OSC client, sending OSC messages to a server listening on port 5500
 */
import oscP5.*;
import netP5.*;

NetAddress myRemoteLocation;

void setup() {
  size(400,400);
  frameRate(25);
  myRemoteLocation = new NetAddress("127.0.0.1",5500);
}

void draw() {
  background(0);  
}

// sending messages when key pressed 
void keyPressed() {
  OscMessage myMessage;
  switch(key) {
    case('1'):
    myMessage = new OscMessage("/X");
    // create an OSC message with address pattern /Y
    for(int i=0;i<400;i++) {
      // add an int to the osc message
      myMessage.add(int(random(255)));
    }
    // we can just flush the message here. 
    // OscP5.flush is a static function and we dont need to declare
    // an instance of oscP5.
    OscP5.flush(myMessage, myRemoteLocation);
    break;
    case('2'):
    // create an OSC message with address pattern /Y
    myMessage = new OscMessage("/Y");
    for(int i=0;i<400;i++) {
      // add an int to the osc message
      myMessage.add(int(random(255))); 
    }
    // we can just flush the message here. 
    // OscP5.flush is a static function and we dont need to declare
    // an instance of oscP5.
    OscP5.flush(myMessage, myRemoteLocation);
    break;
  }
}
 

Sojamo, i still haven't found a way to do it  

Can you help me ?