i would do something like this:

make an array to record your movements. you can simply record your position in every frame at the first position in the array and shift older ones, so you always have your last positions. the length of your array will be the length of your tail. you can also add some values to all the positions saved in your array in every frame, this will add some extra motion to your tail. just in case you don't want your tail to just follow exactly the path you have moved your object.

so far you've got points you can connect to a line. you can then change the strokeweight of this line during connecting the points. you'll get a shape that is bigger at the beginning and gets smaller towards the end.
another option is drawing ellipses at every position of your array. if the distance between the ellipses is small enough, you can get a similar shape. this would be better if you run in opengl where you can't have big strokeweights.
the more advanced version to get to the grass-look would be to calculate the outline of the shape you want by adding some decreasing offset to your arraypositions. you then have twice as much points as your arraylength. make a shape of these by connecting them with vertex-calls.

another extra could be an additional dimension, you could add a noise to the z-dimension and use lights to get grass-like shading.
you can also use a PImage to texture that shape with a png of a nice grassleaf. you would have to add two extra parameters with each call to vertex to map the image to the mesh.
hope this helps

some kind of underwatertail....
in case you don't know about perlinnoise, check the
processing reference for noise(), it's really great for motion and floating around and things like that.
it's important to feed it with very small and changing values. then it can solve lots of troubles.

maybe something like this:

import processing.opengl.*;

float x,y,t;
float[] xpos=new float[100];
float[] ypos=new float[100];
void setup(){
 size(400,400,OPENGL);
 smooth();
 noStroke();
 x=y=200;
 for(int i=0;i<100;i++){
   xpos[i]=x;
   ypos[i]=y;
 }
}


void draw(){
 background(255);

 //motion
 t=frameCount/200.0;
 x=noise(t,0)*width;
 y=noise(t,1)*height;


 //shift array
 for(int i=1;i<100;i++){
   xpos[i-1]=xpos[i]+(noise(t,4)-0.5)*2.0;
   ypos[i-1]=ypos[i]+(noise(t,5)-0.5)*2.0;
 }
 xpos[99]=x;
 ypos[99]=y;


 //draw tail
 fill(100,255,0);
 beginShape(TRIANGLE_STRIP);
 for(int i=99;i>0;i--){
   vertex(xpos[i],ypos[i]);
   vertex(xpos[i]+i/5.0,ypos[i]);
 }

 endShape();
 fill(0,255,0);
 beginShape(TRIANGLE_STRIP);
 for(int i=99;i>0;i--){
   vertex(xpos[i],ypos[i]);
   vertex(xpos[i]-i/5.0,ypos[i]);
 }
 endShape();


 //draw object
 fill(0,100,0);
 ellipse(x,y,40,20);

}