The easiest way to do this is simply to turn off the window frames and position it at the top left corner of your second screen.

I have blogged this technique before, the code looks like this:

Code:

import processing.opengl.*;

void setup(){
  size(400,400,OPENGL);
  background(0);

  // set location - needs to be in setup()
  // set x parameter depending on the resolution of your 1st screen
  frame.setLocation(1024,0);
}

void draw(){
  stroke(255);
  line(0,0,200,200);
}  

public void init() {
  frame.setUndecorated(true); // works.

  // call PApplet.init() to take care of business
  super.init();
} 

You could of course detect the size of your screens in code, so you wouldn't have to set it manually.

Not sure what you mean by "more advanced", but in general this would be the normal way to have one window cover one screen while the other screen functions as normal. You can't use the Java fullscreen mode, since that would take over both screens completely.

If you wanted to make sure the application window is always on top of everything else, you could always add the following after the setLocation command:

Code:

frame.setAlwaysOnTop(false); 

I found something I'd like to share with you...
Good news: I found the solution to the cryptic error message "The frame is displayable" -- simply add this
frame.removeNotify();
will change it to non-displayable and thus remove the compilation error.  (You may need to make it displayable again after frame.setUndecorated(true)
Bad news:
   frame.setLocation(1020,200);  // no effect
I am not able to get it to change the display location no matter what x y location I use.
Anyone knows about the changes since 2007 that can shine a light on this issue?

this has been working so far for me (processing 101)

if you overload init()

void init(){
 frame.dispose();  
 frame.setUndecorated(true);
 super.init();  
}

then in setup(), you can after size()
 //set at second screen  
 frame.setLocation(1280,0);

This solution worked pretty well for me, but I wanted to make my code automatically detect the second screen's location and dimensions. This required using GraphicsConfiguration or GraphicsDevice.

I modified some code I found from Java's 2D API, (sorry, I can't post the link since this is my first post, but just google "Rendering in a Multi-Screen Environment" and it should come up first.)

Then I combined it with some some of the code posted above. It works pretty well, as long as you don't change the screen resolution or positioning while the applet is running

Also, I'm not using opengl, so I don't know what would change if you were.

Code:

Rectangle monitor = new Rectangle();

void setup() { 
  // Get second screen details and save as Rectangle monitor
  GraphicsEnvironment ge = GraphicsEnvironment.getLocalGraphicsEnvironment();
  GraphicsDevice[] gs = ge.getScreenDevices();
  // gs[1] gets the *second* screen. gs[0] would get the primary screen
  GraphicsDevice gd = gs[1];
  GraphicsConfiguration[] gc = gd.getConfigurations();
  monitor = gc[0].getBounds();
  
  println(monitor.x + " " + monitor.y + " " + monitor.width + " " + monitor.height);
  size(monitor.width, monitor.height);
  background(0);
}

void draw() {
  frame.setLocation(monitor.x, monitor.y);
  frame.setAlwaysOnTop(true); 
  stroke(255);
  line(0,0,width/2,height/2);
}  

public void init() {
  frame.removeNotify();
  frame.setUndecorated(true);
  super.init();
} 

Hope this helps someone!