Hi,

Ok, here's my approach. For a sketch I choose to draw lines, and not use vertices. I was wondering if I could do this with less code (more to the point).

For x, y, and z coordinates for the mobius strip wikipedia gives formulea. In those formula there are parameters v and u, and I let for-loops run through those parameters.

Here's my code:

int t;
float[] x, y, z, xPrev, yPrev, zPrev;
 
void setup() {
 size(400, 400, P3D);
}

void draw() {
 background(255);
 pushMatrix();
 translate(200, 200);
 rotateX(radians(t));
 
 //rotate mobius strip
 t = (t+1) % 360;
 
 //run through 360 degrees
 for(int u=0; u<361; u++) {
   
   //uu is radian translation of degrees
   float uu = radians(u);
   
   //arrays to store 5 points per perpendicular line on strip  
   x = new float[5];
   y = new float[5];
   z = new float[5];
   int index = 0;
   for (float v=-1; v<=1; v+=0.5) {
     //calculate coordinates, following parametrization (from wikipedia)
     float xCoord = 100*(1+(v/2)*cos(uu/2))*cos(uu);
     float yCoord = 100*(1+(v/2)*cos(uu/2))*sin(uu);
     float zCoord = 100*(v/2)*sin(uu/2);
     x[index] = xCoord;
     y[index] = yCoord;
     z[index] = zCoord;
     index++;
   }
   
   //if there is more than 1 point start drawing
   if(u>0) {
     for(int i=0; i<5; i++) {
       line(x[i], y[i], z[i], xPrev[i], yPrev[i], zPrev[i]);
       if(u%10 == 0 && i>0 ) {
         line(x[i-1], y[i-1], z[i-1], x[i], y[i], z[i]);
       }
     }
   }

   xPrev = x;
   yPrev = y;
   zPrev = z;
 }
 popMatrix();

}

Groetjes, BEnm