Hello!

I am trying to code a program which first loads a picture and then checks every pixel's rgb values.

If the red value < 128, the red value of this pixel in the new picture will be 0. Otherwise it will be 255.
Same for green and blue.

Finally the program creates a new picture with rgb values either 0 or 255.

The code I wrote:

Code:

PImage pic;

void setup(){
  pic = loadImage("http://processing.org/img/processing_beta_cover.gif");
  size(800,800);
}

void draw(){
  
  background(255);
    
  for(int row=0; row<pic.width; row=row+1) {
  for(int col=0; col<pic.height; col=col+1) {
    
  color pixelcolor=pic.get(row, col);
  
  if ( red(pic) < 128) { red(pixelcolor) = 0; }
  else { red(pic) = 255; }
     
  if ( green(pic) < 128) { green(pixelcolor) = 0; }
  else { green(pic) = 255; }
     
  if ( blue(pic) < 128) { blue(pixelcolor) = 0; }
  else { blue(pic) = 255; }
	 
  }
 }

image(pic,0,0);
}
 

When starting the program I get this error:

Semantic Error: No applicable overload for a method with signature "red(processing.core.PImage)" was found in type "processing.core.PApplet". Perhaps you wanted the overloaded version "float red(int $1);" instead?

Can anybody give me a hint what's wrong?

your testing and setting of pixel colours is wrong in 2 ways.

1: red(pic) is wrong because pic is an image, not a specific colour.

2: red(pixelcolour)=0; will have no effect, what you're effectively saying is 126 = 0; red(pixelcolour) just returns a value, it doesn't give you access to change the colour.

Here's a better method:
Code:

//inside your loop...
color pixelcolor=pic.get(row,col);
int newRed, newGreen, newBlue;
if(red(pixelcolor)<128)
  newRed=0;
else
  newRed=255;

if(green(pixelcolor)<128)
  newGreen=0;
else
  newGreen=255;

if(blue(pixelcolor)<128)
  newBlue=0;
else
  newBlue=255;

pic.set(row,col,color(newRed,newGreen,newBlue);
 

Also you probably should put pic.loadPixels(); after background(...), and pic.updatePixels(); before the image(...); to make sure that your changes are noticed.

yes, loadPixels() is a good idea, even though it's not necessary now, but will be for future releases. size() should also be first in setup()!

a geekier/speedier version:

Code:

PImage pic, thresh;

void setup() {
  size(400, 400); // this should *always* come first, see the reference

  pic = loadImage("http://www.google.com/intl/en_ALL/images/logo.gif"); 
  pic.loadPixels();

  thresh = createImage(pic.width, pic.height, RGB);
  int count = pic.width*pic.height;
  for (int i = 0; i < count; i++) {
    int p = pic.pixels[i];
    int t = 0xFF000000;

    if ((p & 0x800000) != 0) {
	t |= 0xFF0000;
    }
    if ((p & 0x8000) != 0) {
	t |= 0xFF00;
    }
    if ((p & 0x80) != 0) {
	t |= 0xFF;
    }
    thresh.pixels[i] = t;
  }
  thresh.updatePixels();
  image(thresh, 0, 0);
}