Okay, a few things.

You might want to get into the habit of declaring your variables before you call setup.  In your example, you declared your img variable in setup which scopes it to setup and nowhere else.  This means you can only use it in setup because the rest of the sketch doesnt know what 'img' is. This is probably why you also declared it in your draw method as well.  So a good thing to get used to is to declare your PImage outside of setup and then handle loadImage inside of setup.

Also, you dont want to constantly call loadImage.  You only need to call it once.

So, all I am doing here is translating to the center of the screen with translate(300,200) and rotating around that point with rotate(angle).  Then I draw the image but since it draws from the upper left corner by default, I offset the image to minus half its width and minus half its height.  This places the center of the photo at the translate point and voila, image rotates around its center point.

Make sense?

Code:

PImage img;
float step;
float angle;

void setup() 
{ 
  size(600,400);
  frameRate(60);
  img  = loadImage("1154.jpg"); 
  step = 1; 
} 

void draw(){ 
  background(0);
  angle = angle+0.2/step; 
  
  translate(300,200);
  rotate(angle); 
  image(img, -img.width/2, -img.height/2);
  
  step = step*1.03; 
  if (step > 100){
    print("Done"); 
    noLoop(); 
  } 
} 
 
void mousePressed(){ 
  step = 0; 
}