I think if you are going to develop a two-way relationship between your particles then you might as well throw some trigonometry into the equation. I've written out some code below which demonstrates circumnavigation. You could just add a little translation and rotation to get the effect of a rect rotating around an ellipse. It's not exactly what you're describing but given a form of rotation where you'll know about co-ordinate changes I'm sure you'll be able to figure the rest out.
Code:

Rotator one, two;
void setup(){
  size(400, 400);
  one = new Rotator(175, 175);
  two = new Rotator(225, 225);
}
void draw(){
  background(0);
  smooth();
  one.draw();
  two.draw();
  if(keyPressed){
    one.circumnavigate(two.x, two.y);
  } else {
    two.circumnavigate(one.x, one.y);
  }
}
class Rotator{
  float x,y;
  Rotator(float x, float y){
    this.x = x;
    this.y = y;
  }
  void draw(){
    ellipse(x, y, 20, 20);
  }
  void circumnavigate(float x, float y){
    float theta = atan2(this.y - y, this.x - x);
    float distance = dist(this.x, this.y, x, y);
    theta += 0.05;
    this.x = x + cos(theta) * distance;
    this.y = y + sin(theta) * distance;
  }
}