Have you had a look at pushMatrix and popMatrix?
http://processing.org/reference/pushMatrix_.html
http://processing.org/reference/popMatrix_.html

I don't know whether you're stuck on those or just on moving something in space, so I've made an example that hopefully covers both:

float radius; // radius of orbit
float angle; // current angle (in degrees)
float speed; // angle to increment orbit by each loop
float rotation; // rotation of the scene

void setup () {
 size(300,300,P3D);
 radius = 100;
 angle = 0;
 speed = 0.5;
 rotation = radians(0);
}

void draw () {
 background(255);

 // this translate isn't push/popped
 // so it'll apply generally (i.e. to the whole scene)
 translate(width/2,height/2,0); // puts the cartesian point 0,0,0 in the middle of the window
 rotation += radians(0.1);
 rotateX(rotation); // rotates the whole scene on the x axis

 // calculate new position of the box
 float xpos = sin(radians(angle))*radius;
 float ypos = cos(radians(angle))*radius;
 angle += speed;

 // this translate has pushMatrix and popMatrix before and after it
 // so it only applies to the created box
 pushMatrix();
 fill(123);
 translate(xpos,ypos,0);
 rotateZ(radians(angle)*-1); // orient the cube to its orbit
 box(20,20,20);
 popMatrix();

 // this cirlce is stationary in space
 noFill();
 ellipse(0,0,200,200);

}

I'm not sure what you want to do with the up key. How do you know which way a box is facing?

If you want to sort of give it a front and a back, and move it forwards whatever direction it's facing in, then you're probably best off looking at vectors, which is a whole new kettle of wolves.

As for Cos and Sin, if you need to know about trigonometry, start here:
http://en.wikipedia.org/wiki/Trigonometry#About_trigonometry

Then this which hopefully explains what's going on:
http://redcrayon.do.sapo.pt/orebeeeet.png

The cube rotating correctly can be sorted by switching round your rotate and translate:

import processing.opengl.*;

float radius; // radius of orbit  
float angle; // current angle (in degrees)  
float speed; // angle to increment orbit by each loop  
float rotation; // rotation of the scene  
float xpos;
float ypos;



void setup () {  
 size(900,900,OPENGL);  
 radius = 100;  
 angle = 0;  
 speed = 0.5;  
 rotation = radians(0);  
}  

void draw ()  
{  
 int turnT = 0;
 background(255);  
 translate(width/2,height/2,0);
 if(keyPressed)
 {
   if(keyCode  == LEFT)
    {
xpos = sin(radians(angle))*radius;  
ypos = cos(radians(angle))*radius;  
angle += speed;
  }
   else if(keyCode == UP)
   {
ypos += speed;
turnT = 1;
   }
 }
 pushMatrix();  
 fill(123);  
 translate(xpos,ypos,0);  
 rotateZ(radians(angle)*-1);
 box(20,20,20);  
 popMatrix();  
 
 noFill();  
 ellipse(0,0,200,200);  
}

I mentioned above im trying to develop a 3d space sim. i have done a decent amount of work trying to get this program functioning correctly. i have now encoutered a problem and was wondering if anybody here could possibly help me out

i have the Ship (cube in this case as the ship requires many Shapes) moving around the screen.The + and - keys make the box move forward and backward and the UP, DOWN, LEFT and RIGHT keys control its direction. the problem is that the cube will only move correctly once its aligned (parallel) to one of the axis;

EG when the program starts you can accelerate and then push the up and down keys and its responds as it should but as soon as you push left or right it goes all over the place.

this also happens if you (at the start of the program) push left or right after accelerating. but the once you push Up or down it goes out of control

Please help because there is no way im gonna be able to figure this out on my own.

Thanks again Graham.

I have included the code below.

import processing.opengl.*;

float godY;
float godX;
float godZ;
float godXrot;
float godYrot;
float godZrot;
float speed;
float angleX;
float angleY;
float angleZ;
int planeMovement = 0;
float xpos,ypos,zpos;

Vector[] corners;

void setup()
{
 size(1280,1024,OPENGL);
 godX = 0;
 godY = 0;
 godZ = 0;
 //----------
 godXrot = 0;
 godYrot = 0;
 godZrot = 0;
 //----------
 speed = 0.1;
 //----------
 xpos = 0;
 ypos = 0;
 zpos = 0;
 //----------
 angleZ = 180;
 angleY = 0;
 angleX = 0;
 speed = 0.0;
 //----------
}

void draw()
{
 scale(.5);
 stroke(0);
 lights();
 background(0);
 translate(width,height,0);
 POR();
 pushMatrix();
 noStroke();
 translate(500,300,-200);
 fill(255,0,255);
 sphere(40);
 translate(-1100, -500, 300);
 fill(255,255,0);
 sphere(60);
 popMatrix();
 fill(0);
 
 if(planeMovement == 0)
 {
    moveX();
 }
 else
 {
    moveZ();
 }
 movement();
 translate(godX,godY,godZ);
 rotate(-angleZ/57.5);
 rotateX(-angleX/57.5);
 fill(255,24,78);
 box(60);
}

void movement()
{
   godX = godX + xpos;
   godY = godY + ypos;
   godZ = godZ + zpos;
}
void moveZ()
{
   xpos = (sin(radians(angleZ))*speed)*-1;
   ypos = (cos(radians(angleZ))*speed)*-1;
}
void moveX()
{  
   ypos = cos(radians(angleX))*speed;
   zpos = sin(radians(angleX))*speed;
}

void POR()
{
   stroke(255,0,0);
   line(-200, 0, 0, 200, 0, 0); //X is red
   stroke(0,255,0);
   line(0, -200, 0, 0, 200, 0); //Y is green
   stroke(0,0,255);
   line(0, 0, -200, 0, 0, 200); //Z is Blue
}

void keyPressed()
{
   if(keyCode == DELETE)
   {
     //angleY = angleY - .2;
   }
   else if(keyCode == LEFT)
   {
     planeMovement = 1;
     angleZ = angleZ + 1;    
   }
   else if(keyCode == RIGHT)
   {
     planeMovement = 1;
     angleZ = angleZ - 1;      
   }
   else if(keyCode == UP)
   {
     planeMovement = 0;
     angleX = angleX + 1;  
   }
   else if(keyCode == DOWN)
   {
     planeMovement = 0;
     angleX = angleX - 1;    
   }
   else if(key == '-')
   {
         speed = speed + 0.1;
   }
   else if(key == '=')
   {
         speed = speed - 0.1;
   }  
}