float x = 150;			 //starting position x axis
float y = 200;			 //starting position y axis
float speed = 0;		     //speed of the ship
float drag = .994;		   //amount of drag or friction on ship
float mangle, fangle;		//moving angle, floating angle
 
boolean[] keysPressed = new boolean[128];  
 
void setup()
{
  size(300, 400);		    //uh... window size
}
 
void draw()
{
  keyState();
  move();
  wrap();
  background(0);		     //background color
 
  pushMatrix();
  translate(x, y);
  rotate(fangle);		    //rotate the ship according to the floating angle
  noFill();			    //no fill on the ship (wireframe)  
  stroke(255);			 //color of wireframe
  ship();				//drawing the ship
  popMatrix();
  translate(x, y);
}

void ship()
{
  beginShape(POLYGON);	     //start of shape draw for ship
  vertex(-1, -4);
  vertex(1, -4);
  vertex(3, -6);
  vertex(3, -8);
  vertex(5, 2);
  vertex(7, 4);
  vertex(4, 7);
  vertex(1, 5);
  vertex(-1, 5);
  vertex(-4, 7);
  vertex(-7, 4);
  vertex(-5, 2);
  vertex(-3, -8);
  vertex(-3, -6);
  endShape();			  //end of shape draw for ship
} 
  
void keyPressed() {  
  keysPressed[keyCode] = true;  
}  
 
void keyReleased() {  
  keysPressed[keyCode] = false;  
}  
 
void move()
{
  x += sin(mangle)*speed;			
  y -= cos(mangle)*speed;			
  speed = speed * drag;  
}
 
void wrap()
{
  if(y < - 8){		   //top screen test
    y = height + 8;	    //wrap ship to bottom
  }else if(y > height + 8){  //bottom screen test
    y = - 8;		     //wrap ship to top
  }
  
  if(x < - 8){		   //left screen test
    x = width + 8;	     //wrap ship to right
  }else if(x > width + 8){   //right screen test
    x = - 8;		     //wrap ship to left
  }
}
 
void keyState()
{
  if(keysPressed[UP]){
    speed += .125;
    mangle = fangle;	   //set the moving angle to be what the floating angle is set to be
  }
  if(keysPressed[LEFT]){
    if(keysPressed[UP]){
	mangle -= .0625;
	fangle = mangle;	 //if up is pressed, set floating angle to be mangle, so there's no twitching
    }else{
	fangle -= .0625;
    }
    
  }
  if(keysPressed[RIGHT]){
    if(keysPressed[UP]){
	mangle += .0625;
	fangle = mangle;	 //if up is pressed, set floating angle to be mangle, so there's no twitching
    }else{
	fangle += .0625;
    }
  }
}